P_Bpcontacts_Address

@AbapCatalog.sqlViewName: 'P_MD_BPC_ADR'
@VDM.private: true
@VDM.viewType: #BASIC
define view P_Bpcontacts_Address as select from but052
inner join but000  on but052.partner2 = but000.partner

association [1..1] to adcp as _AddressDetails on $projection.AddressID = _AddressDetails.addrnumber and $projection.Person = _AddressDetails.persnumber
association [1..1] to P_Bpcontacts_Telephone as _Telephone on $projection.AddressID = _Telephone.AddressID and $projection.Person = _Telephone.Person
association [1..1] to P_Bpcontacts_Mobilephone as _MobilePhone on $projection.AddressID = _MobilePhone.AddressID and $projection.Person = _MobilePhone.Person
association [1..1] to adr3 as _Fax on $projection.AddressID = _Fax.addrnumber and $projection.Person = _Fax.persnumber
association [1..1] to adr6 as _Email on $projection.AddressID = _Email.addrnumber and $projection.Person = _Email.persnumber
{
  key but052.relnr as Relationship,
  key but052.partner2 as BusinessPartner,
  key but052.addrnumber as AddressID,
  key but000.persnumber as Person,
  but052.xdfadr as IsDefaultAddress,
  _AddressDetails.building as Building,
  _AddressDetails.floor as Floor,
  _AddressDetails.roomnumber as RoomNumber,
  _Telephone.InternationalPhoneNumber,
  _Telephone.PhoneCountry,
  _Telephone.PhoneNumber,
  _Telephone.PhoneNumberExtension,
  _MobilePhone.InternationalMobilePhoneNumber,
  _MobilePhone.MobilePhoneCountry,
  _MobilePhone.MobilePhoneNumber,
  _MobilePhone.MobilePhoneExtension,
  _Fax.faxnr_long as InternationalFaxNumber,
  _Fax.country as FaxCountry,
  _Fax.fax_number as FaxNumber,
  _Fax.fax_extens as FaxNumberExtension,
  _Email.smtp_addr as EmailAddress,  
  
  _AddressDetails,
  _Telephone,
  _MobilePhone,
  _Fax,
  _Email
}
   
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_BPCONTACTS_MOBILEPHONE",
"P_BPCONTACTS_TELEPHONE",
"ADCP",
"ADR3",
"ADR6",
"BUT000",
"BUT052"
],
"ASSOCIATED":
[
"P_BPCONTACTS_MOBILEPHONE",
"P_BPCONTACTS_TELEPHONE",
"ADCP",
"ADR3",
"ADR6"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/