P_BadDebtReserveCustomers

@AbapCatalog.sqlViewName: 'PBADDEBTRSVCUST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_BadDebtReserveCustomers
  with parameters
    P_KeyDate : sydate
  as select from I_OperationalAcctgDocItem
  association [1..1] to P_DoubtReceivablesCreditAcct as _DoubtfulReceivables on  _DoubtfulReceivables.CreditGLAccount = $projection.GLAccount
  association [0..1] to I_Customer                   as _ReferencedCustomer  on  _ReferencedCustomer.Customer = $projection.ReferencedCustomer
  association [0..1] to I_OperationalAcctgDocItem    as _ReferencedDocument  on  _ReferencedDocument.AccountingDocument     = $projection.ReferencedDocument
                                                                             and _ReferencedDocument.CompanyCode            = $projection.CompanyCode
                                                                             and _ReferencedDocument.FiscalYear             = $projection.ReferencedFiscalYear
                                                                             and _ReferencedDocument.AccountingDocumentItem = $projection.ReferencedDocumentItem
{
  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key AccountingDocumentItem,

      case SpecialGLCode
        when '' then cast( '' as fis_kunnr )  // Key 50 or 40: calculated allowance - no direct customer assignment

        else cast( Customer as fis_kunnr )    // Key 19 or 09: special allowance - direct customer assignment

      end                                                                     as AssignedCustomer,

      case SpecialGLCode
        when '' then AmountInCompanyCodeCurrency               //Key 50 or 40 - calculated allowance

        else 0                                                 //Key 19 or 09

      end                                                                     as CalcdAllwncForDoubtfulAccts,

      case SpecialGLCode
        when '' then 0                                         //Key 50 or 40

        else AmountInCompanyCodeCurrency                       //Key 19 or 09 - special allowance

      end                                                                     as SpclAllwncForDoubtfulAccts,

      SpecialGLCode,
      cast(substring(AssignmentReference, 1, 10) as fis_kunnr)                as ReferencedCustomer,
      cast(substring(AssignmentReference, 1, 10) as farp_belnr_d)             as ReferencedDocument,
      cast(substring(AssignmentReference, 11, 3) as fis_buzei )               as ReferencedDocumentItem,
      cast(substring(AssignmentReference, 14, 4) as fis_gjahr  )              as ReferencedFiscalYear,

      AccountingDocumentType,
      PostingDate,
      cast('00000000' as farp_netdt)                                          as NetDueDate,

      case SpecialGLCode
        when '' then cast('CA' as farp_bdr_document_category)
        else cast('SP' as farp_bdr_document_category)
      end                                                                     as BadDebtReserveDocumentCategory,

      GLAccount,
      AmountInCompanyCodeCurrency,
      CompanyCodeCurrency,
      AssignmentReference,

      _ReferencedCustomer,
      _ReferencedDocument
}
where
           GLAccount     =  _DoubtfulReceivables.CreditGLAccount
  and      PostingDate   <= :P_KeyDate
  and(
    (
           SpecialGLCode =  ''
      and(
           PostingKey    =  '50'
        or PostingKey    =  '40'
      )
    )
    or(
           SpecialGLCode != ''
      and(
           PostingKey    =  '19'
        or PostingKey    =  '09'
      )
    )
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OPERATIONALACCTGDOCITEM",
"P_DOUBTRECEIVABLESCREDITACCT"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_OPERATIONALACCTGDOCITEM",
"P_DOUBTRECEIVABLESCREDITACCT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/