P_ActvENTERPRISEPROJPLNCOSTS

@AbapCatalog.sqlViewName: 'PACTENTPRJPLN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_ActvENTERPRISEPROJPLNCOSTS
  as select from P_ActvPROJECTSWITHPROJCAT6   as Project
    inner join   I_FinancialPlanningEntryItem as ProjCstLineItm on ProjCstLineItm.ProjectInternalID = Project.ProjectInternalID
                                                                and ProjCstLineItm.Project = Project.Project
    inner join   P_IsLeadingLedger            as Ledger         on ProjCstLineItm.Ledger = Ledger.Ledger
    inner join   P_PROJECTSEMTAGACC           as SemanticTag    on  ProjCstLineItm.ControllingArea = SemanticTag.ControllingArea
                                                                and ProjCstLineItm.GLAccount       = SemanticTag.HierarchyNodeVal
                                                                and ProjCstLineItm.ChartOfAccounts = SemanticTag.HierarchyNodeClass
{

  key ProjCstLineItm.FiscalYear,
  key ProjCstLineItm.LedgerFiscalYear, //key

  key ProjCstLineItm.FiscalPeriod,
  key ProjCstLineItm.FiscalYearPeriod,
  key ProjCstLineItm.PostingDate,
  key SemanticTag.SemanticTag,
  key ProjCstLineItm.PlanningCategory,
      cast(cast('' as abap.char (10)) as farp_belnr_d )                                  as AccountingDocument,
      cast(cast('' as abap.char (6)) as fis_docln )                                      as LedgerGLLineItem,
      cast('00000000'as fis_cpdat)               as CreationDate,
      Project.CompanyCode, //key

      Project.ProfitCenter, //key

      Project.ControllingArea,
      Project.ProjectUUID,
      ProjCstLineItm.ProjectInternalID,
      Project.ProjectType,
      Project.ProjectExternalID as Project,
      @Semantics.currencyCode: true
      Project.ProjectCurrency                    as ControllingObjectCurrency,
      @Semantics.currencyCode: true
      ProjCstLineItm.GlobalCurrency,
      Project.ProjectDescription,
      Project.AvailabilityControlProfile,
      Project.AvailabilityControlIsActive,
      Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
      Project._AvailabilityCtrlProfile.BudgetCurrencyRole,
      Project.ProjectSummaryTaskUUID,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'ControllingObjectCurrency'
      sum(ProjCstLineItm.AmountInObjectCurrency) as AmountInObjectCurrency,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      sum(ProjCstLineItm.AmountInGlobalCurrency) as AmountInGlobalCurrency


}
group by
  Project.CompanyCode,
  Project.ProfitCenter,
  Project.ControllingArea,
  Project.ProjectUUID,
  ProjCstLineItm.ProjectInternalID,
  Project.ProjectType,
  ProjCstLineItm.FiscalYear,
  ProjCstLineItm.LedgerFiscalYear,
  Project.ProjectExternalID,
  Project.ProjectCurrency,
  ProjCstLineItm.GlobalCurrency,
  ProjCstLineItm.FiscalPeriod,
  ProjCstLineItm.FiscalYearPeriod,
  ProjCstLineItm.PostingDate,
  SemanticTag.SemanticTag,
  Project.ProjectDescription,
  Project.AvailabilityControlProfile,
  Project.AvailabilityControlIsActive,
  Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
  Project._AvailabilityCtrlProfile.BudgetCurrencyRole,
  Project.ProjectSummaryTaskUUID,
  ProjCstLineItm.PlanningCategory
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_AVAILABILITYCTRLPROFILE",
"I_FINANCIALPLANNINGENTRYITEM",
"P_ACTVPROJECTSWITHPROJCAT6",
"P_ISLEADINGLEDGER",
"P_PROJECTSEMTAGACC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/