P_Activitylist

@AbapCatalog.sqlViewName: 'PACTLIST'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #BASIC

define view P_Activitylist as select from P_RootNode
inner join   P_PICMStatus     as IssueStatuses on P_RootNode.application    = IssueStatuses.application and
                                                  P_RootNode.issue_category = IssueStatuses.category and
                                                  P_RootNode.issue_type     = IssueStatuses.type and
                                                  P_RootNode.stat_cd        = IssueStatuses.stacd
inner join /iam/d_act_root as ActivityList on P_RootNode.db_key             = ActivityList.par_issue_uuid
inner join /iam/d_act_date as ActivityDate on ActivityList.db_key           = ActivityDate.parent_key
association [0..*] to I_MasterProject as _MasterProject on $projection.MasterProjectUUID = _MasterProject.ProjectUUID
{
  P_RootNode.id as MasterProjectUUID,
  _MasterProject.MasterProject,
  P_RootNode.issue_id,
  P_RootNode.application,
  ActivityList.activity_id,
  ActivityList.act_category,
  ActivityList.act_type,
  ActivityList.act_template,
  ActivityDate.date_time,
  substring( cast( ActivityDate.date_time as abap.char(17) ), 1, 8) as ActivityEndDate,

  _MasterProject
}
where P_RootNode.application = 'ICM' and
      P_RootNode.archiving_status <> '02' and // Exclude Archived Objects

      ( IssueStatuses.iam_status = '60' or IssueStatuses.iam_status = '05' ) and // Show only New or In Process Issues/Change Requests

      IssueStatuses.exclude_in_list = '' and // Fliter issues based on exclude functionality

      ActivityDate.role_cd = 'P02' and // End date of activity

//      ActivityDate.date_time < TSTMP_CURRENT_UTCTIMESTAMP() and

      ( ActivityList.cea_status = '' or ActivityList.cea_status = '1' or ActivityList.cea_status = '2' )  // New and In Process








/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MASTERPROJECT",
"P_PICMSTATUS",
"P_ROOTNODE",
"/IAM/D_ACT_DATE",
"/IAM/D_ACT_ROOT"
],
"ASSOCIATED":
[
"I_MASTERPROJECT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/