P_AR_SupplierPaymentBPDetail

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view entity P_AR_SupplierPaymentBPDetail
  as select from           P_AR_SupplierPaymentUnion     as Payment

    inner join             I_Supplier                    as Supplier         on Supplier.Supplier = Payment.Supplier

    left outer to one join I_JournalEntryItemOneTimeData as OneTimeAccountBP on  OneTimeAccountBP.CompanyCode        = Payment.CompanyCode
                                                                             and OneTimeAccountBP.AccountingDocument = Payment.ReltdDocAccountingDocument
                                                                             and OneTimeAccountBP.FiscalYear         = Payment.RelatedDocumentFiscalYear

{
  key Payment.StatryRptgEntity,
  key Payment.StatryRptCategory,
  key Payment.StatryRptRunID,
  key Payment.CompanyCode,
  key Payment.FiscalYear,
  key Payment.AccountingDocument,
  key Payment.AccountingDocumentItem,
  key Payment.ClearingInformationIndex,
  key Payment.ReltdDocAccountingDocument,
  key Payment.RelatedDocumentItemNumber,
      Payment.PaymentDate,
      Payment.PaymentMethod,
      Payment.CompanyCodeCountry,
      Payment.CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      Payment.PaytAmountInCoCodeCurrency,
      Payment.HouseBank,
      Payment.PaymentGLAccount,
      Payment._GLAccountInCompanyCode,
      Payment.RelatedDocumentFiscalYear,
      Payment.ReltdDocTransactionCurrency,
      @Semantics.amount.currencyCode: 'ReltdDocTransactionCurrency'
      Payment.ReltdDocAmtInTransCurrency,
      Payment.ReltdSpclGLTransacType,
      Supplier.Supplier,

      cast(
        case Supplier.IsOneTimeAccount
          when 'X' then OneTimeAccountBP.BusinessPartnerName1
          when ''  then Supplier.BusinessPartnerName1
      end as businesspartnername )                 as BusinessPartnerName,

      cast(
        case Supplier.IsOneTimeAccount
          when 'X' then OneTimeAccountBP.Country
          when ''  then Supplier.Country
      end as glo_partner_country preserving type ) as BusinessPartnerCountry,

      cast(
        case Supplier.IsOneTimeAccount
          when 'X' then OneTimeAccountBP.TaxID1
          when ''  then Supplier.TaxNumber1
      end as stcd1 preserving type )               as TaxNumber1,

      cast(
        case Supplier.IsOneTimeAccount
          when 'X' then OneTimeAccountBP.IsNaturalPerson
          when ''  then Supplier.IsNaturalPerson
      end as bu_natural_person preserving type )   as IsNaturalPerson,

      Payment.CheckIssuerTaxNumber,
      Payment.EndorsedBankTaxNumber,
      Payment.EndorsedCheckNumber
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYITEMONETIMEDATA",
"I_SUPPLIER",
"P_AR_SUPPLIERPAYMENTUNION"
],
"ASSOCIATED":
[
"I_GLACCOUNTINCOMPANYCODE"
],
"BASE":
[
"P_AR_SUPPLIERPAYMENTUNION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/