P_AR_EDplOtherPerceptionFilter

@AbapCatalog.sqlViewName: 'PAREDUPPRCPTFLTR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_AR_EDplOtherPerceptionFilter
  with parameters
    P_RptgAmountIsInTransCrcy : fiar_use_transaction_currency
    
 as select from P_AR_JournalEntry as JournalEntry
    inner join  P_AR_TaxItem      as TaxItem on  TaxItem.CompanyCode        = JournalEntry.CompanyCode
                                             and TaxItem.AccountingDocument = JournalEntry.AccountingDocument
                                             and TaxItem.FiscalYear         = JournalEntry.FiscalYear 
{
  key JournalEntry.CompanyCode,
  key JournalEntry.FiscalYear,
  key JournalEntry.AccountingDocument,
  key TaxItem.TaxItem,
      TaxItem.CompanyCodeCountry,
      TaxItem.StRpTaxClassification,  
      JournalEntry.DocumentDate,
      JournalEntry.PostingDate,
      JournalEntry.ReportingDate,
      JournalEntry.AccountingDocumentType,
      JournalEntry.AR_Branch,
      JournalEntry.AR_OfficialDocumentNumber,
      JournalEntry.AR_PrintCharacter,
      JournalEntry.DocumentReferenceID,
      TaxItem.AddressRegion,
      TaxItem.MunicipalJurisdiction,
      
      cast(
        case $parameters.P_RptgAmountIsInTransCrcy
          when 'X'
            then TaxItem.TransactionCurrency
          else TaxItem.CompanyCodeCurrency
        end as glo_reporting_currency preserving type
      )                           as ReportingCurrency,  
      
      cast(
        case $parameters.P_RptgAmountIsInTransCrcy
          when 'X'
            then TaxItem.TaxAmountInTransCrcy
          else TaxItem.TaxAmountInCoCodeCrcy
        end as glo_tax_amount_rptg_crcy preserving type
      )                           as TaxAmountInRptgCrcy     
      
}

where ( JournalEntry.IsReversed <> 'X' or JournalEntry.AR_OfficialDocumentNumber is not initial )
  and ( TaxItem.StRpTaxClassification = 'MP' or TaxItem.StRpTaxClassification = 'GI' or TaxItem.StRpTaxClassification = 'GP' )
  and TaxItem.TaxRate <> 0  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_AR_JOURNALENTRY",
"P_AR_TAXITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/