P_AR_CustomerReceivableTotal

@AbapCatalog.sqlViewName: 'PACUSTRECTOT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.private:true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D

define view P_AR_CustomerReceivableTotal
  as select from I_OperationalAcctgDocItem
    inner join   I_Customer as Customer on I_OperationalAcctgDocItem.Customer = Customer.Customer
{
  key I_OperationalAcctgDocItem.CompanyCode,
  key I_OperationalAcctgDocItem.FiscalYear,
  key I_OperationalAcctgDocItem.AccountingDocument,
  key case
        when Customer.FiscalAddress <> ''
          then Customer.FiscalAddress
        else Customer.Customer
      end                                                                                           as Customer,
      I_OperationalAcctgDocItem.FinancialAccountType,
      cast( max(I_OperationalAcctgDocItem.NetDueDate) as farp_netdt preserving type )               as NetDueDate,
      cast( max(I_OperationalAcctgDocItem.ClearingDate) as fis_augdt preserving type )              as ClearingDate,
      cast( max(I_OperationalAcctgDocItem.ClearingJournalEntry) as fis_augbl preserving type )      as ClearingAccountingDocument,
      
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode:true
      I_OperationalAcctgDocItem.CompanyCodeCurrency,
      
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast( sum(I_OperationalAcctgDocItem.AmountInCompanyCodeCurrency) as fis_hsl preserving type ) as AmountInCompanyCodeCurrency,
      
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      I_OperationalAcctgDocItem.TransactionCurrency,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast( sum(I_OperationalAcctgDocItem.AmountInTransactionCurrency) as fis_wsl preserving type ) as AmountInTransactionCurrency,
      
      I_OperationalAcctgDocItem._CompanyCode,
      I_OperationalAcctgDocItem._JournalEntry,
      I_OperationalAcctgDocItem._CompanyCodeCurrency,
      I_OperationalAcctgDocItem._TransactionCurrency,
      
      I_OperationalAcctgDocItem.DebitCreditCode
}
where
      I_OperationalAcctgDocItem.FinancialAccountType       = 'D'
  and I_OperationalAcctgDocItem.IsUsedInPaymentTransaction = ''
group by
  I_OperationalAcctgDocItem.CompanyCode,
  I_OperationalAcctgDocItem.FiscalYear,
  I_OperationalAcctgDocItem.AccountingDocument,
  I_OperationalAcctgDocItem.FinancialAccountType,
  I_OperationalAcctgDocItem.Customer,
  Customer.Customer,
  Customer.FiscalAddress,
  I_OperationalAcctgDocItem.CompanyCodeCurrency,
  I_OperationalAcctgDocItem.TransactionCurrency,
  I_OperationalAcctgDocItem.DebitCreditCode
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_OPERATIONALACCTGDOCITEM"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_JOURNALENTRY"
],
"BASE":
[
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/