P_ARProcessFlowJournalEntryDoc

@AbapCatalog.sqlViewName: 'PARPROCFLOWACC'
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_UserContactCard']
@EndUserText.label: 'Journal Entry Document details for AR process flow'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@DataAging.noAgingRestriction: true
define view  P_ARProcessFlowJournalEntryDoc
  as
select from I_OperationalAcctgDocItem
//association [0..1] to I_UserContactCard          as _UserContactCard       on  $projection.accountingdoccreatedbyuser  = _UserContactCard.ContactCardID


  association [0..1] to I_Customer         as _Customer        on $projection.Customer                   = _Customer.Customer
  association [1..1] to I_UserContactCard  as _UserContactCard on $projection.accountingdoccreatedbyuser = _UserContactCard.ContactCardID
  
association [0..1] to I_InternalOrder      as _InternalOrder                 on  $projection.OrderID           = _InternalOrder.InternalOrder  
association [0..1] to I_Order              as _Order                         on  $projection.OrderID           = _Order.OrderID    

{
key CompanyCode,
key FiscalYear,
key AccountingDocument,
key AccountingDocumentItem,
//key LedgerGLLineItem,


    FinancialAccountType,
    DebitCreditCode,

    ReferenceDocumentType,
    OriginalReferenceDocument as ReferenceDocument,
    BillingDocument,
    PostingDate,
    NetDueDate,

    @Semantics.currencyCode:true
    TransactionCurrency,
    @Semantics.amount.currencyCode: 'TransactionCurrency'
    AmountInTransactionCurrency,

    @Semantics.currencyCode:true
    CompanyCodeCurrency,
    @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
    AmountInCompanyCodeCurrency,

    ClearingDate,
    @VDM.lifecycle.status:    #DEPRECATED
    @VDM.lifecycle.successor: 'ClearingJournalEntryFiscalYear'
    ClearingDocFiscalYear,
    ClearingJournalEntryFiscalYear,
    @VDM.lifecycle.status:    #DEPRECATED
    @VDM.lifecycle.successor: 'ClearingJournalEntry'
    ClearingAccountingDocument,
    ClearingJournalEntry,

    _JournalEntry.AccountingDocCreatedByUser,

    DocumentDate,

    FiscalPeriod,
    _FiscalPeriod._Text[1:Language = $session.system_language].FiscalPeriodName,

    Customer,
    _Customer.CustomerName,
    Supplier,
    AccountingDocumentType,
    _AccountingDocumentType._Text[1:Language = $session.system_language].AccountingDocumentTypeName,

    _JournalEntry.Ledger,
    _JournalEntry._Ledger.IsLeadingLedger,
    BusinessArea,
    FunctionalArea,
    ProfitCenter,
    CostCenter,
    GLAccount,
    Segment,
    ControllingArea,
    //DistributionChannel,

    //_JournalEntry.OrganizationDivision,

    Plant,
    //_JournalEntry.SalesOrganization,

    ValuationArea,
    SalesDocument as SalesOrder,
    _GLAccountInCompanyCode,
    _Supplier,
    _Customer,
    _AccountingDocumentType,
    _SalesDocument,
    _InternalOrder,
    _FixedAsset,
    FixedAsset,
    MasterFixedAsset,
    OrderID,
               
      //Auth

    _GLAccountInCompanyCode.AuthorizationGroup,
    _Supplier.AuthorizationGroup                 as SupplierFinsAuthorizationGrp,
    _Customer.AuthorizationGroup                 as CustomerFinsAuthorizationGrp,
    _AccountingDocumentType.AuthorizationGroup   as AcctgDocTypeAuthorizationGroup,
    _SalesDocument.SalesOrderType,
    _InternalOrder.OrderType,
    _FixedAsset.AssetClass,
    
    _UserContactCard,
    _CompanyCode,
    _Plant
//    _SalesOrder


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_CUSTOMER",
"I_FISCALPERIODFORCOCODETEXT",
"I_FISCALYEARPERIODFORCMPNYCODE",
"I_FIXEDASSET",
"I_GLACCOUNTINCOMPANYCODE",
"I_INTERNALORDER",
"I_JOURNALENTRY",
"I_LEDGER",
"I_OPERATIONALACCTGDOCITEM",
"I_SALESORDER",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_FIXEDASSET",
"I_GLACCOUNTINCOMPANYCODE",
"I_INTERNALORDER",
"I_ORDER",
"I_PLANT",
"I_SALESORDER",
"I_SUPPLIER",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/