P_ARJrnlEntrItmOpenRec1_CC

@VDM.viewType: #COMPOSITE
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view entity P_ARJrnlEntrItmOpenRec1_CC
  with parameters
    P_KeyDate       : vdm_v_key_date,
    P_LeadingLedger : fins_ledger
    

  as select from    I_JournalEntryOperationalView as OpenReceivables
{
  key OpenReceivables.CompanyCode                                    as CompanyCode,
  key OpenReceivables.FiscalYear                                     as FiscalYear,
  key OpenReceivables.AccountingDocument                             as AccountingDocument,
  key OpenReceivables.LedgerGLLineItem                               as LedgerGLLineItem,

      OpenReceivables.AccountingDocumentCategory,
      OpenReceivables.AccountingDocumentType,

      OpenReceivables.AccountingDocumentItem                         as AccountingDocumentItem,
      OpenReceivables.InvoiceReference                               as InvoiceReference,
      OpenReceivables.InvoiceItemReference                           as InvoiceItemReference,
      OpenReceivables.InvoiceReferenceFiscalYear                     as InvoiceReferenceFiscalYear,
      OpenReceivables.ClearingDate                                   as ClearingDate,
      OpenReceivables.PostingDate                                    as PostingDate,
      OpenReceivables.DocumentDate                                   as DocumentDate,
      OpenReceivables.FinancialAccountType                           as FinancialAccountType,
      OpenReceivables.Customer                                       as Customer,
      OpenReceivables.FollowOnDocumentType                           as FollowOnDocumentType,
      OpenReceivables.NetDueDate                                     as NetDueDate,
      OpenReceivables.SpecialGLCode                                  as SpecialGLCode,
      OpenReceivables.SpecialGLTransactionType                       as SpecialGLTransactionType,
      OpenReceivables.GLAccount                                      as GLAccount,
      OpenReceivables.ProfitCenter                                   as ProfitCenter,
      OpenReceivables.FunctionalArea                                 as FunctionalArea,
      OpenReceivables.BusinessArea                                   as BusinessArea,
      OpenReceivables.Segment                                        as Segment,
      OpenReceivables.BillingDocument                                as BillingDocument,
      OpenReceivables.AssignmentReference                            as AssignmentReference,
      OpenReceivables.CompanyCodeCurrency                            as CompanyCodeCurrency,
      
      @Semantics.amount.currencyCode: 'COMPANYCODECURRENCY' 
      OpenReceivables.AmountInCompanyCodeCurrency                    as AmountInCompanyCodeCurrency,
      OpenReceivables.TransactionCurrency                            as TransactionCurrency,
      @Semantics.amount.currencyCode: 'TRANSACTIONCURRENCY' 
      OpenReceivables.AmountInTransactionCurrency                    as AmountInTransactionCurrency,
      
      OpenReceivables.Reference1IDByBusinessPartner                  as Reference1IDByBusinessPartner,
      OpenReceivables.Reference2IDByBusinessPartner                  as Reference2IDByBusinessPartner,
      OpenReceivables.Reference3IDByBusinessPartner                  as Reference3IDByBusinessPartner,
      OpenReceivables.PaymentMethod                                  as PaymentMethod,
      OpenReceivables.ChartOfAccounts                                as ChartOfAccounts,
      OpenReceivables.ControllingArea                                as ControllingArea,
      OpenReceivables.WBSElementExternalID,
      OpenReceivables.WBSElementInternalID,
      OpenReceivables.ProjectExternalID, 
      OpenReceivables.ProjectInternalID, 
      
      _Customer,
      _CompanyCode,
      _JournalEntry,
      _SpecialGLCode,
      _FinancialAccountType,
      _ChartOfAccounts,
      _GLAccountInChartOfAccounts,
      _ProfitCenter,
      _CurrentProfitCenter,
      OpenReceivables._Customer._AddressRepresentation.Country       as CustomerCountry,
      OpenReceivables._Customer._AddressRepresentation.Region        as CustomerRegion,
      OpenReceivables._Customer.CustomerAccountGroup,
      OpenReceivables._CompanyCode.Country                           as CompanyCodeCountry,
      OpenReceivables._Customer.AuthorizationGroup                   as CustomerBasicAuthorizationGrp,
      OpenReceivables._Customer.CustomerClassification,
      OpenReceivables._Customer.CustomerCorporateGroup,

      _CompanyCode._Country                                          as _CompanyCodeCountry,
      _ControllingArea,
      _Customer._CustomerClassification,
      _FunctionalArea,
      _BusinessArea,
      _Segment,
      _WBSElementBasicData,
      _ProjectBasicData,
      _WBSElementExternalID,
      _ProjectExternalID
}
where  OpenReceivables.SourceLedger                = $parameters.P_LeadingLedger
  and  OpenReceivables.Ledger                      = $parameters.P_LeadingLedger
  and  OpenReceivables.FinancialAccountType        = 'D'
  and  OpenReceivables.AccountingDocumentCategory  =  ''
  and  OpenReceivables.AccountingDocumentItem      <> '000'
  and  OpenReceivables.NetDueDate                  <> '00000000'
  and  OpenReceivables.NetDueDate                  is not null  // be sure to get only operational items with BSEG item

  and(
       OpenReceivables.ClearingDate                >  $parameters.P_KeyDate
    or OpenReceivables.ClearingDate                =  '00000000'
  )
  and  OpenReceivables.PostingDate                 <= $parameters.P_KeyDate              
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS_2",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_JOURNALENTRYOPERATIONALVIEW"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_CUSTOMER",
"I_CUSTOMERCLASSIFICATION",
"I_FINANCIALACCOUNTTYPE",
"I_FUNCTIONALAREA",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_JOURNALENTRY",
"I_PROFITCENTER",
"I_PROJECTBASICDATA",
"I_PROJECTBYEXTERNALID",
"I_SEGMENT",
"I_SPECIALGLCODE",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYEXTERNALID"
],
"BASE":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_JOURNALENTRYOPERATIONALVIEW"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/