P_ARJrnlEntrItmOpenRec1

@VDM.viewType: #COMPOSITE
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view entity P_ARJrnlEntrItmOpenRec1
  with parameters
    P_KeyDate : sydate

  as select from    I_JournalEntryOperationalView as OpenReceivables
    
    association [0..1] to I_FiscalYearForCompanyCode   as _FiscalYear                 on  $projection.FiscalYear  = _FiscalYear.FiscalYear
                                                                                      and $projection.CompanyCode = _FiscalYear.CompanyCode
                                                                                      
    association [0..1] to I_AccountingClerk            as _AccountingClerk            on  _AccountingClerk.CompanyCode     = $projection.CompanyCode
                                                                                      and _AccountingClerk.AccountingClerk = $projection.accountingclerk                                                                                 
    
    association [0..1] to I_GLAccountInChartOfAccounts as _ReconciliationAccount      on  _ReconciliationAccount.ChartOfAccounts = $projection.ChartOfAccounts
                                                                                      and _ReconciliationAccount.GLAccount       = $projection.reconciliationaccount                                                                                  
                                                                                      
    association [0..1] to I_CustomerAccountGroup       as _CustomerAccountGroup       on  _CustomerAccountGroup.CustomerAccountGroup = $projection.customeraccountgroup
                                                                                      
    association [0..1] to I_PaymentMethod              as _PaymentMethod              on  _PaymentMethod.PaymentMethod = $projection.PaymentMethod
                                                                                      and _PaymentMethod.Country       = $projection.country
                                                                                      
    association [0..1] to I_Country                    as _CustomerCountry            on  _CustomerCountry.Country = $projection.CustomerCountry
  
    association [0..1] to I_Region                     as _CustomerRegion             on  _CustomerRegion.Region  = $projection.CustomerRegion
                                                                                      and _CustomerRegion.Country = $projection.CustomerCountry
                                                                                      
    association [0..1] to I_CustomerCompany            as _CustomerCompany            on  _CustomerCompany.CompanyCode = $projection.CompanyCode
                                                                                      and _CustomerCompany.Customer    = $projection.Customer 
{
  key OpenReceivables.CompanyCode                                    as CompanyCode,
  key OpenReceivables.FiscalYear                                     as FiscalYear,
  key OpenReceivables.AccountingDocument                             as AccountingDocument,
  key OpenReceivables.LedgerGLLineItem                               as LedgerGLLineItem,

      OpenReceivables.AccountingDocumentCategory,
      OpenReceivables.AccountingDocumentType,

      OpenReceivables.AccountingDocumentItem                         as AccountingDocumentItem,
      OpenReceivables.InvoiceReference                               as InvoiceReference,
      OpenReceivables.InvoiceItemReference                           as InvoiceItemReference,
      OpenReceivables.InvoiceReferenceFiscalYear                     as InvoiceReferenceFiscalYear,
      OpenReceivables.ClearingDate                                   as ClearingDate,
      OpenReceivables.PostingDate                                    as PostingDate,
      OpenReceivables.DocumentDate                                   as DocumentDate,
      OpenReceivables.FinancialAccountType                           as FinancialAccountType,
      OpenReceivables.Customer                                       as Customer,
      OpenReceivables.FollowOnDocumentType                           as FollowOnDocumentType,
      OpenReceivables.NetDueDate                                     as NetDueDate,
      OpenReceivables.SpecialGLCode                                  as SpecialGLCode,
      OpenReceivables.SpecialGLTransactionType                       as SpecialGLTransactionType,
      OpenReceivables.GLAccount                                      as GLAccount,
      OpenReceivables.ProfitCenter                                   as ProfitCenter,
      OpenReceivables.BusinessArea                                   as BusinessArea,
      OpenReceivables.Segment                                        as Segment,
      OpenReceivables.BillingDocument                                as BillingDocument,
      OpenReceivables.AssignmentReference                            as AssignmentReference,
      OpenReceivables.CompanyCodeCurrency                            as CompanyCodeCurrency,
      
      @Semantics.amount.currencyCode: 'COMPANYCODECURRENCY' 
      OpenReceivables.AmountInCompanyCodeCurrency                    as AmountInCompanyCodeCurrency,
      OpenReceivables.TransactionCurrency                            as TransactionCurrency,
      @Semantics.amount.currencyCode: 'TRANSACTIONCURRENCY' 
      OpenReceivables.AmountInTransactionCurrency                    as AmountInTransactionCurrency,
      
      OpenReceivables.Reference1IDByBusinessPartner                  as Reference1IDByBusinessPartner,
      OpenReceivables.Reference2IDByBusinessPartner                  as Reference2IDByBusinessPartner,
      OpenReceivables.Reference3IDByBusinessPartner                  as Reference3IDByBusinessPartner,
      OpenReceivables.PaymentMethod                                  as PaymentMethod,
      OpenReceivables.ChartOfAccounts                                as ChartOfAccounts,
      OpenReceivables.ControllingArea                                as ControllingArea,
      
      _Customer,
      _CompanyCode,
      _JournalEntry,
      _SpecialGLCode,
      _FinancialAccountType,
      _ChartOfAccounts,
      _GLAccountInChartOfAccounts,
      _ProfitCenter,
      _CurrentProfitCenter,
      OpenReceivables._Customer._StandardAddress.Country             as CustomerCountry,
      OpenReceivables._Customer._StandardAddress.Region              as CustomerRegion,
      _CustomerCompany.ReconciliationAccount,
      OpenReceivables._Customer.CustomerAccountGroup,
      _CustomerCompany.AccountingClerk,
      OpenReceivables._CompanyCode.Country,
      OpenReceivables._Customer.AuthorizationGroup                   as CustomerBasicAuthorizationGrp,
      _CustomerCompany.AuthorizationGroup                            as CustomerFinsAuthorizationGrp,
      OpenReceivables._Customer.CustomerClassification,
      _CustomerCompany.CustomerAccountNote,                                            
      OpenReceivables._Customer.CustomerCorporateGroup,   
      
      _FiscalYear,
      _AccountingClerk,
      _ReconciliationAccount,
      _CustomerAccountGroup,
      _PaymentMethod,
      _CompanyCode._Country,
      _ControllingArea,
      _CustomerCountry,
      _CustomerRegion,
      _CustomerCompany,
      _Customer._CustomerClassification
}
where  OpenReceivables.SourceLedger                = '0L'
  and  OpenReceivables.Ledger                      = '0L'
  and  OpenReceivables.FinancialAccountType        = 'D'
  and  OpenReceivables.AccountingDocumentCategory  =  ''
  and  OpenReceivables.AccountingDocumentItem      <> '000'
  and  OpenReceivables.NetDueDate                  <> '00000000'
  and  OpenReceivables.NetDueDate                  is not null  // be sure to get only operational items with BSEG item

  and(
       OpenReceivables.ClearingDate                >  $parameters.P_KeyDate
    or OpenReceivables.ClearingDate                =  '00000000'
  )
  and  OpenReceivables.PostingDate                 <= $parameters.P_KeyDate              
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_CUSTOMERCOMPANY",
"I_JOURNALENTRYOPERATIONALVIEW"
],
"ASSOCIATED":
[
"I_ACCOUNTINGCLERK",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_CUSTOMER",
"I_CUSTOMERACCOUNTGROUP",
"I_CUSTOMERCLASSIFICATION",
"I_CUSTOMERCOMPANY",
"I_FINANCIALACCOUNTTYPE",
"I_FISCALYEARFORCOMPANYCODE",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_JOURNALENTRY",
"I_PAYMENTMETHOD",
"I_PROFITCENTER",
"I_REGION",
"I_SPECIALGLCODE"
],
"BASE":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_JOURNALENTRYOPERATIONALVIEW"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/