P_ACMTrdgContrItemTypeQty

@AbapCatalog.sqlViewName: 'PCONTRITEM'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@VDM.private: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

define view P_ACMTrdgContrItemTypeQty
  as select from wbhk             as Header
    inner join   /accgo/t_cak_typ as ContractTypeDetails on Header.tctyp = ContractTypeDetails.tctyp
    inner join   wbhi             as ContractItem        on Header.tkonn = ContractItem.tkonn
    inner join   wbhd             as Business            on Header.tkonn = Business.tkonn
    inner join   mara             as Material            on ContractItem.matnr = Material.matnr

{
  key ContractItem.tkonn     as ContractNum,
  key ContractItem.tposn     as TradingContractItem,
  key ContractItem.tposn_sub as ContractSubItem,
      @Semantics.quantity.unitOfMeasure: 'TrdgContractItemUnitOfMeasure'
      case ContractItem.menge
      when 0
      then ContractItem.kwmeng
      else ContractItem.menge
      end                    as TradingContractItemQuantity,
      @Semantics.unitOfMeasure: true
      case ContractItem.meins
      when ''
      then ContractItem.vrkme
      else ContractItem.meins
      end                    as TrdgContractItemUnitOfMeasure,

      ContractItem.matnr     as ContractMaterial,
      ContractItem.werks     as ContractPlant,
      Header.tctyp           as TradingContractType,
      Header.company_code    as CompanyCode,
      Header.erdat           as DocumentDate,
      Header.ernam           as TradingContractCreatedBy,
      Header.vkorg           as SalesOrganization,
      Header.vtweg           as DistributionChannel,
      Header.spart           as Division,
      Business.ekorg         as PurchasingOrganization,
      Business.ekgrp         as PurchasingGroup,
      Material.commodity     as Commodity,
      Header.kunnr           as CustomerName,
      Business.elifn         as SupplierName
}
where

  (
       ContractTypeDetails.contract_type = 'R'
    or ContractTypeDetails.contract_type = 'C'
    or ContractTypeDetails.contract_type = 'I'
    or ContractTypeDetails.contract_type = 'S'
    or ContractTypeDetails.contract_type = 'T'
  )
  and  Business.tposn                    = '000000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/ACCGO/T_CAK_TYP",
"MARA",
"WBHD",
"WBHI",
"WBHK"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/