N_ChgRecdObjPgRefRateRtg

@AbapCatalog.sqlViewName:'NCHGRCDOBJPGRRT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Auxillary view Chg Recd Ref rate Routing'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.preserveKey:true
@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant']
}

@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass:  #CUSTOMIZING,
                          sizeCategory: #S}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@VDM.auxiliaryEntity.for.entity: 'C_ChgRecdRefRateRtgTskList'

define view N_ChgRecdObjPgRefRateRtg
  as select from           I_ChgRecdRefRateRtgTskListBsc as ReferenceRateRoutingBsc
    left outer to one join I_BillOfOperations            as ReferenceRateRouting on  ReferenceRateRoutingBsc.ChgRecRefInternalKey1 = ReferenceRateRouting.BillOfOperationsType
                                                                                 and ReferenceRateRoutingBsc.ChgRecRefInternalKey2 = ReferenceRateRouting.BillOfOperationsGroup
                                                                                 and ReferenceRateRoutingBsc.ChgRecRefInternalKey3 = ReferenceRateRouting.BillOfOperationsVariant

  association [1..1] to C_ChgRecdRefRateRtgTskListVH  as _RefRateRoutingVH        on  $projection.BillOfOperationsType    = _RefRateRoutingVH.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _RefRateRoutingVH.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _RefRateRoutingVH.BillOfOperationsVariant
  association [1..1] to I_ChangeRecordDraftTP         as _ChangeRecordTP          on  $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefRateRtgTskListBsc as _RefRateRoutingExtension on  $projection.ChangeRecordReferenceUUID = _RefRateRoutingExtension.ChangeRecordReferenceUUID
  association [1..1] to C_ItmRelRefRateRtgTskListVH   as _ChangeRecordItemRelVH   on  $projection.ChangeRecordItemRelevance              = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                  and $projection.ChangeRecordType                       = _ChangeRecordItemRelVH.ChangeRecordType
                                                                                  and (
                                                                                     $projection.ChangeRecordReferenceType               = _ChangeRecordItemRelVH.ChangeRecordReferenceType
                                                                                     or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
                                                                                   )
{

          @UI.hidden: true
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @UI.lineItem:[{
                position:10,
                   label: 'Group',
                importance:#HIGH }
              ]
          @UI.identification: {position: 10, importance: #HIGH}
          @Consumption.valueHelp: '_RefRateRoutingVH'
          @ObjectModel.mandatory: true
          @Search.defaultSearchElement: true
          cast(BillOfOperationsGroup as r_plnnr preserving type)   as BillOfOperationsGroup,
          @UI.hidden: true
          BillOfOperationsType                                     as BillOfOperationsType,
          @UI.lineItem:[{
               position:25,
               label: 'Group Counter ',
               importance:#HIGH }
             ]
          @UI.identification: {position: 30, importance: #HIGH }
          cast(BillOfOperationsVariant as r_plnal preserving type) as BillOfOperationsVariant,
          ChangeRecordItemProcgStatus,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordTP.ChangeRecordType                         as ChangeRecordType,

          @UI.hidden: true
          ChangeRecordUUID,
          @UI.hidden: true
          ChangeRecordReferenceType,
          @UI.hidden: true
          ParentChangeRecordRefUUID,
          @UI.lineItem:[{
                      position:35,
                      importance:#HIGH }
                    ]
          @UI.identification: {position:50, importance: #HIGH}
          ChangeRecordItemRelevance,
          _ChangeRecordTP.ChangeRecordLifecycleStatus              as ChangeRecordLifecycleStatus,

          @UI.hidden: true
          ChangeRecordReference,

          @Semantics.user.createdBy: true
          CreatedByUser,
          @UI.hidden: true
          CreationDateTime,
          @UI.hidden: true
          LastChangeDateTime,
          _ChangeRecordTP,
          _ChangeRecordItemRelVH,
          _RefRateRoutingVH
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHANGERECORDDRAFTTP",
"I_CHGRECDREFRATERTGTSKLISTBSC"
],
"ASSOCIATED":
[
"C_CHGRECDREFRATERTGTSKLISTVH",
"C_ITMRELREFRATERTGTSKLISTVH",
"E_CHGRECDREFRATERTGTSKLISTBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/