N_ChgRecdObjPgRefOpSet

@AbapCatalog.sqlViewName:'NCHGRCDOBJPGROS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Auxillary view Chg Recd Ref Op Set'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.preserveKey:true
@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant']
}

@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass:  #CUSTOMIZING,
                          sizeCategory: #S}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@VDM.auxiliaryEntity.for.entity: 'C_ChgRecdRefOpSetTskList'

define view N_ChgRecdObjPgRefOpSet
  as select from           I_ChgRecdRefOpSetTskListBsc as ReferenceOpSetBsc
    left outer to one join I_BillOfOperations          as ReferenceOpSet on  ReferenceOpSetBsc.ChgRecRefInternalKey1 = ReferenceOpSet.BillOfOperationsType
                                                                         and ReferenceOpSetBsc.ChgRecRefInternalKey2 = ReferenceOpSet.BillOfOperationsGroup
                                                                         and ReferenceOpSetBsc.ChgRecRefInternalKey3 = ReferenceOpSet.BillOfOperationsVariant

  association [1..1] to C_ChgRecdRefOpSetTskListVH  as _RefOpSetVH            on  $projection.BillOfOperationsType    = _RefOpSetVH.BillOfOperationsType
                                                                              and $projection.BillOfOperationsGroup   = _RefOpSetVH.BillOfOperationsGroup
                                                                              and $projection.BillOfOperationsVariant = _RefOpSetVH.BillOfOperationsVariant
  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP        on  $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefOpSetTskListBsc as _RefOpSetExtension     on  $projection.ChangeRecordReferenceUUID = _RefOpSetExtension.ChangeRecordReferenceUUID
  association [1..1] to C_ChgRecdRlvnceRefOpSetVH   as _ChangeRecordItemRelVH on  $projection.ChangeRecordItemRelevance              = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                              and $projection.ChangeRecordType                       = _ChangeRecordItemRelVH.ChangeRecordType
                                                                              and (
                                                                                 $projection.ChangeRecordReferenceType               = _ChangeRecordItemRelVH.ChangeRecordReferenceType
                                                                                 or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
                                                                               )
{

          @UI.hidden: true
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @UI.lineItem:[{
                position:10,
                   label: 'Group',
                importance:#HIGH }
              ]
          @UI.identification: {position: 10, importance: #HIGH}
          @Consumption.valueHelp: '_RefOpSetVH'
          @ObjectModel.mandatory: true
          @Search.defaultSearchElement: true
          cast(BillOfOperationsGroup as r_plnnr preserving type)   as BillOfOperationsGroup,
          @UI.hidden: true
          BillOfOperationsType                                     as BillOfOperationsType,
          @UI.lineItem:[{
               position:25,
               label: 'Group Counter ',
               importance:#HIGH }
             ]
          @UI.identification: {position: 30, importance: #HIGH }
          cast(BillOfOperationsVariant as r_plnal preserving type) as BillOfOperationsVariant,
          ChangeRecordItemProcgStatus,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordTP.ChangeRecordType                         as ChangeRecordType,

          @UI.hidden: true
          ChangeRecordUUID,
          @UI.hidden: true
          ChangeRecordReferenceType,
          @UI.hidden: true
          ParentChangeRecordRefUUID,
          @UI.lineItem:[{
                      position:35,
                      importance:#HIGH }
                    ]
          @UI.identification: {position:50, importance: #HIGH}
          ChangeRecordItemRelevance,
          _ChangeRecordTP.ChangeRecordLifecycleStatus              as ChangeRecordLifecycleStatus,

          @UI.hidden: true
          ChangeRecordReference,

          @Semantics.user.createdBy: true
          CreatedByUser,
          @UI.hidden: true
          CreationDateTime,
          @UI.hidden: true
          LastChangeDateTime,
          _ChangeRecordTP,
          _ChangeRecordItemRelVH,
          _RefOpSetVH
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHANGERECORDDRAFTTP",
"I_CHGRECDREFOPSETTSKLISTBSC"
],
"ASSOCIATED":
[
"C_CHGRECDREFOPSETTSKLISTVH",
"C_CHGRECDRLVNCEREFOPSETVH",
"E_CHGRECDREFOPSETTSKLISTBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/