N_ChgRecdObjPgEquipTskList

@AbapCatalog.sqlViewName:'NCHGRCDOBJEQUIP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Auxillary view for ESH-Chg Recd Equip TL'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.preserveKey:true
@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant']
}

@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass:  #CUSTOMIZING,
                          sizeCategory: #S}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@VDM.auxiliaryEntity.for.entity: 'C_ChgRecdObjPgEquipTskList'

define view N_ChgRecdObjPgEquipTskList
  as select from           I_ChgRecdRefEquipTskListBsc as EquipTskListReference
    left outer to one join I_BillOfOperations          as EquipTskList on  EquipTskListReference.ChgRecRefInternalKey1 = EquipTskList.BillOfOperationsType
                                                                       and EquipTskListReference.ChgRecRefInternalKey2 = EquipTskList.BillOfOperationsGroup
                                                                       and EquipTskListReference.ChgRecRefInternalKey3 = EquipTskList.BillOfOperationsVariant

  association [1..1] to C_ChgRecdEquipTskListVH       as _EquipTskListVH        on  $projection.BillOfOperationsType    = _EquipTskListVH.BillOfOperationsType
                                                                                and $projection.BillOfOperationsGroup   = _EquipTskListVH.BillOfOperationsGroup
                                                                                and $projection.BillOfOperationsVariant = _EquipTskListVH.BillOfOperationsVariant
  association [1..1] to I_ChangeRecordDraftTP         as _ChangeRecordTP        on  $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefEquipTskListBsc   as _EquipTskListExtension on  $projection.ChangeRecordReferenceUUID = _EquipTskListExtension.ChangeRecordReferenceUUID
  association [1..1] to C_ChgRecdItmRelEquipTskListVH as _ChangeRecordItemRelVH on  $projection.ChangeRecordItemRelevance              = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                and $projection.ChangeRecordType                       = _ChangeRecordItemRelVH.ChangeRecordType
                                                                                and (
                                                                                   $projection.ChangeRecordReferenceType               = _ChangeRecordItemRelVH.ChangeRecordReferenceType
                                                                                   or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
                                                                                 )
{

          @UI.hidden: true
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @UI.lineItem:[{
                position:10,
                   label: 'Group',
                importance:#HIGH }
              ]
          @UI.identification: {position: 10, importance: #HIGH}
          @Consumption.valueHelp: '_EquipTskListVH'
          @ObjectModel.mandatory: true
          @Search.defaultSearchElement: true
          cast(BillOfOperationsGroup as r_plnnr preserving type)   as BillOfOperationsGroup,
          @UI.hidden: true
          BillOfOperationsType                                     as BillOfOperationsType,
          @UI.lineItem:[{
               position:25,
               label: 'Group Counter ',
               importance:#HIGH }
             ]
          @UI.identification: {position: 30, importance: #HIGH }
          cast(BillOfOperationsVariant as r_plnal preserving type) as BillOfOperationsVariant,
          ChangeRecordItemProcgStatus,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordTP.ChangeRecordType                         as ChangeRecordType,

          @UI.hidden: true
          ChangeRecordUUID,
          @UI.hidden: true
          ChangeRecordReferenceType,
          @UI.hidden: true
          ParentChangeRecordRefUUID,
          @UI.lineItem:[{
                      position:35,
                      importance:#HIGH }
                    ]
          @UI.identification: {position:50, importance: #HIGH}
          ChangeRecordItemRelevance,
          _ChangeRecordTP.ChangeRecordLifecycleStatus              as ChangeRecordLifecycleStatus,

          @UI.hidden: true
          ChangeRecordReference,

          @Semantics.user.createdBy: true
          CreatedByUser,
          @UI.hidden: true
          CreationDateTime,
          @UI.hidden: true
          LastChangeDateTime,
          _ChangeRecordTP,
          _ChangeRecordItemRelVH
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHANGERECORDDRAFTTP",
"I_CHGRECDREFEQUIPTSKLISTBSC"
],
"ASSOCIATED":
[
"C_CHGRECDEQUIPTSKLISTVH",
"C_CHGRECDITMRELEQUIPTSKLISTVH",
"E_CHGRECDREFEQUIPTSKLISTBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/