I_ZA_StRpRevenueExpenseLineC

@AbapCatalog.sqlViewName: 'ISRZARVEXLINENC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'South Africa Revenue Expense Lines'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions: true
@VDM.lifecycle.status: #DEPRECATED
@AccessControl.blocking:#BLOCKED_DATA_INCLUDED

define view I_ZA_StRpRevenueExpenseLineC as select from I_StRpTaxItemBoxCube
                                          

left outer join       I_ReceivablesPayablesItem on  I_StRpTaxItemBoxCube.CompanyCode           = I_ReceivablesPayablesItem.CompanyCode
                                                and I_StRpTaxItemBoxCube.AccountingDocument    = I_ReceivablesPayablesItem.AccountingDocument
                                                and I_StRpTaxItemBoxCube.FiscalYear            = I_ReceivablesPayablesItem.FiscalYear
                                                and I_StRpTaxItemBoxCube.TaxCode               = I_ReceivablesPayablesItem.TaxCode
                                                
                                                
left outer join P_T007B_GLO on I_ReceivablesPayablesItem.TransactionTypeDetermination = P_T007B_GLO.ktosl

left outer join P_TimeDepdntVersAssgmtNext as Taxgroupingversion on  Taxgroupingversion.land1 = 'ZA'               
                                                                 and I_StRpTaxItemBoxCube.ReportingDate >= fdatu
                                                                 and I_StRpTaxItemBoxCube.ReportingDate <= fdatu_to 

association [1..*] to I_MaterialText as _MaterialText on $projection.Material = _MaterialText.Material

association [0..1] to I_Currency            as _ReportingCurrency on  $projection.ReportingCurrency = _ReportingCurrency.Currency

 {

  key I_StRpTaxItemBoxCube.CompanyCode,
  key I_StRpTaxItemBoxCube.AccountingDocument,
  key I_StRpTaxItemBoxCube.FiscalYear,
  key I_StRpTaxItemBoxCube.TaxItem,
  key I_StRpTaxItemBoxCube.TaxCode,
  key I_StRpTaxItemBoxCube.TransactionTypeDetermination,
  key I_StRpTaxItemBoxCube.TaxBox,
  key I_StRpTaxItemBoxCube.TaxDeclnAmountType,
  key Taxgroupingversion.verstax as TaxItemGroupingVersion,
  key I_StRpTaxItemBoxCube.DebitCreditCode,
      I_StRpTaxItemBoxCube.TaxRate,
      I_StRpTaxItemBoxCube.TaxType,
      I_StRpTaxItemBoxCube.PostingDate,
      I_StRpTaxItemBoxCube.ReportingDate,
      I_StRpTaxItemBoxCube.TaxCalculationProcedure,
      @Semantics.currencyCode:true
      I_StRpTaxItemBoxCube.CompanyCodeCurrency,
      @Semantics.text: true
      _MaterialText.MaterialName,
      _AccountingDocument._CompanyCode.VATRegistration,
      
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case 
      when AmountInCompanyCodeCurrency < 0
      then -AmountInCompanyCodeCurrency
      else AmountInCompanyCodeCurrency
      end as AmountInCompanyCodeCurrency,          
       
      FinancialAccountType,
      //DocumentItemText,

      I_ReceivablesPayablesItem.Material,
      stazf as CashDiscountIsDeductible,
      CashDiscountAmtInCoCodeCrcy,
      
      @DefaultAggregation:#SUM
       case 
       when Quantity <> 0 then Quantity
       else 1
       end as Quantity,
       
       case 
       when BaseUnit <> '' then BaseUnit
       else 'EA'
       end as BaseUnit,
       
       case 
      when _Customer.Customer <> '' and I_StRpTaxItemBoxCube.TaxType = 'A'
        then 
            case
            when CashDiscountAmtInCoCodeCrcy <> 0
              then 'L11'
              else 'L01'
            end
        else        
      case
      when _Supplier.Supplier <> '' and I_StRpTaxItemBoxCube.TaxType = 'V'  
        then              
          'L06'         
       else
      case I_StRpTaxItemBoxCube.TaxType 
      when 'A'
        then 'L05'
      when 'V' 
        then 'L10'
      else ''  
        end 
        end 
       end as RecordType,
       
       case TaxBox
        when '01' then 'IT1'
        when '02' then 'IT2'
        when '03' then 'IT3'
        when '04' then 'IT4'
        when '05' then 'IT5'
        when '06' then 'IT6'
        when '07' then 'IT7'
        when '08' then 'IT8'
        when '09' then 'IT9'
        when '10' then 'IT10'
        when '11' then 'IT11'
        when '21' then 'OT1'
        when '22' then 'OT2'
        when '23' then 'OT3'
        when '24' then 'OT4'
        when '25' then 'OT5'
        when '26' then 'OT6'
        when '27' then 'OT7'
        when '28' then 'OT8'
        when '29' then 'OT9'
        else ''
       end as ClassGroup,
       
       ReportingCountry,
       
       case 
       when DocumentItemText <> '' then DocumentItemText
       else 
       case
       when AccountingDocumentHeaderText <> '' then AccountingDocumentHeaderText
       else 
       _MaterialText.MaterialName
       end
       end as DocumentItemText,
       
       ReportingCurrency,
       
       _Customer.Customer,
       _Supplier.Supplier,
       _Customer.AuthorizationGroup,
       _TaxCodeText,
       _TaxTypeText,
       _ReportingCurrency,
       
       BusinessPartnerName
       
       
  
      } where ( FinancialAccountType = 'S' and ( I_ReceivablesPayablesItem.TaxType <> 'A' and I_ReceivablesPayablesItem.TaxType <> 'V' ) and TaxDeclnAmountType <> 'B') 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENT",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_MATERIALTEXT",
"I_RECEIVABLESPAYABLESITEM",
"I_STRPTAXITEMBOXCUBE",
"I_SUPPLIER",
"P_T007B_GLO",
"P_TIMEDEPDNTVERSASSGMTNEXT"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_MATERIALTEXT",
"I_TAXCODETEXT",
"I_TAXTYPETEXT"
],
"BASE":
[
"I_STRPTAXITEMBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/