I_WrntyAccountingControlDoc

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IWTYACCCONTR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Warranty accounting and Controlling Docs'
@VDM.viewType: #BASIC
@ObjectModel:{
    representativeKey: 'AccountingDocument',
    usageType:{
        dataClass       : #TRANSACTIONAL,
        serviceQuality  : #D,
        sizeCategory    : #XL
        }
}
define view I_WrntyAccountingControlDoc
  as select from I_WrntyClaimAccountingDocument
    inner join   cobk as ControlDoc on  ControlDoc.kokrs = I_WrntyClaimAccountingDocument.CompanyCode
                                    and ControlDoc.gjahr = I_WrntyClaimAccountingDocument.FiscalYear
                                    and ControlDoc.awkey = I_WrntyClaimAccountingDocument.OriginalReferenceDocument
{
  key I_WrntyClaimAccountingDocument.CompanyCode,
  key ControlDoc.belnr                                   as AccountingDocument,
      ControlDoc.gjahr                                   as FiscalYear,
      ControlDoc.awtyp                                   as ReferenceDocumentType,
      ControlDoc.awkey                                   as OriginalReferenceDocument,
      I_WrntyClaimAccountingDocument.DocumentReferenceID as DocumentReferenceID,
      cast('P' as bstat_d)                               as AccountingDocumentCategory,
      I_WrntyClaimAccountingDocument.WrntyVersionNumber,
      //I_WrntyClaimAccountingDocument.WrntyPartNumber,

      I_WrntyClaimAccountingDocument.WarrantyClaimVersionPartner,
      I_WrntyClaimAccountingDocument.PurchasingOrganization,
      I_WrntyClaimAccountingDocument.Plant,
      I_WrntyClaimAccountingDocument.WarrantyClaimType,
      I_WrntyClaimAccountingDocument.WrntySupplier,
      I_WrntyClaimAccountingDocument.WarrantyCustomer,
      I_WrntyClaimAccountingDocument.WrntyClaimHeaderUUID,
      I_WrntyClaimAccountingDocument._WrntyClaimHeader,
      I_WrntyClaimAccountingDocument._CompanyCode,
      I_WrntyClaimAccountingDocument._Supplier,
      I_WrntyClaimAccountingDocument._Customer
}
where
  I_WrntyClaimAccountingDocument.ReferenceDocumentType = 'WTYD'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WRNTYCLAIMACCOUNTINGDOCUMENT",
"COBK"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_SUPPLIER",
"I_WRNTYCLAIMHEADER"
],
"BASE":
[
"I_WRNTYCLAIMACCOUNTINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/