I_WrkCtrCapShiftIntervalTP

@AbapCatalog.sqlViewName: 'IWCCAPINTERVALTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    modelCategory: #BUSINESS_OBJECT,
    draftEnabled: true,
    writeDraftPersistence: 'CFSWCINTERVAL_D',
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    semanticKey: ['WorkCenterInternalID', 'WorkCenterTypeCode', 'CapacityCategoryAllocation' ,
                   'CapacityInternalID'],
    representativeKey: ['CapacityActiveVersion','ValidityEndDate']                   
}
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@EndUserText.label: 'Work Center Shift Interval'
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_WrkCtrCapShiftIntervalTP 
        as select from I_WorkCenterCapacityInterval as _shiftInterval
       
        association [1..1] to I_WorkCenterCapOverviewTP  as _workCenterResponsible
                on $projection.WorkCenterInternalID = _workCenterResponsible.WorkCenterInternalID
                and $projection.WorkCenterTypeCode = _workCenterResponsible.WorkCenterTypeCode
                and $projection.CapacityCategoryAllocation = _workCenterResponsible.CapacityCategoryAllocation
                and $projection.CapacityInternalID = _workCenterResponsible.CapacityInternalID
{

  key _shiftInterval.WorkCenterInternalID,
  key _shiftInterval.WorkCenterTypeCode,
  key _shiftInterval.CapacityCategoryAllocation,
  key _shiftInterval.CapacityInternalID,
  key cast (_shiftInterval.ValidityEndDate as datub) as ValidityEndDate,
  key cast(_shiftInterval.AvailableCapacityType as kapversakt) as CapacityActiveVersion,
  
     cast (_shiftInterval.ValidityEndDate as datub) as ValidityEndDateForEdit,
  cast (_shiftInterval.ValidityBeginDate as datub) as ValidityBeginDate,
  cast (_shiftInterval.WorkDayRule as kapfabtag) as WorkDayRule,
  cast (_shiftInterval.CapacityNumberOfCapacities as kapanzahl) as  CapacityNumberOfCapacities,
  cast (_shiftInterval.AvailableCapacityIntervalDurn as numc2) as AvailableCapacityIntervalDurn,
  cast (_shiftInterval.CapacityPlanUtilizationPercent as nutzgrad) as CapacityPlanUtilizationPercent,
  cast (_shiftInterval.StdAvailableCapacityIsValid as kap_kopf) as StdAvailableCapacityIsValid,
  cast (_shiftInterval.ShiftSequence as schprog) as ShiftSequence,
  cast ('' as char20 ) as IntervalStatusText,
  cast ('' as cfs_interval_change_status ) as IntervalStatusCode,
  
  
     
  @ObjectModel: {
          association: {
              type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
          }
      }
      _workCenterResponsible ,
      _Capacity
  
    
}
where _shiftInterval.ValidityEndDate >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKCENTERCAPACITYINTERVAL"
],
"ASSOCIATED":
[
"I_CAPACITY",
"I_WORKCENTERCAPOVERVIEWTP"
],
"BASE":
[
"I_WORKCENTERCAPACITYINTERVAL"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/