I_WorkforcePersonSrchHelp

@AbapCatalog.sqlViewName: 'IWFPERSONSHLP'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Search Help for Workforce Person' 
@Search.searchable: true
@Consumption.ranked: true
@ObjectModel.dataCategory:#VALUE_HELP
@Metadata.ignorePropagatedAnnotations: true
define view I_WorkforcePersonSrchHelp  as select distinct from I_WorkforcePerson as a

//left outer join I_PersonWorkAgreement as employment on a.Person = employment.Person "Deprecation of I_Personworkagreement

left outer join I_PersonWorkAgreement_1 as employment on a.Person = employment.Person 

left outer join I_PersonWorkAgrmtStatus as b on employment.PersonWorkAgreement = b.PersonWorkAgreement
                                             and b.EndDate >= $session.system_date //current and future employments


left outer to one join I_BusinessUser as c on a.BusinessPartnerUUID = c.BusinessPartnerUUID
{
   @Search.defaultSearchElement: true
   @Search.ranking: #HIGH
   @Search.fuzzinessThreshold: 0.8 
   key a.Person,
   @EndUserText.label: 'Last Name'
   a._BusinessPartner.BPLastNameSearchHelp as LastName,
   @EndUserText.label: 'First Name'
   a._BusinessPartner.BPFirstNameSearchHelp as FirstName,
   @EndUserText.label: 'Person ID'   
   a.PersonExternalID ,
   @Search.defaultSearchElement: true
   @Search.ranking: #LOW   
   @Search.fuzzinessThreshold: 0.9 
   a.PersonFullName,
   c.UserID,
   @UI.hidden: true
   a.AuthorizationGroup,
   @UI.hidden: true
   @Semantics.booleanIndicator: true
   a.IsBusinessPurposeCompleted,
   
   //Added only for DCL check

   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataControllerSet,                                                                                                                                                                      
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController1,
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController2,
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController3,
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController4,
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController5,                                                                                                                                                                       
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController6,
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController7,
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController8,
   @Consumption.hidden:true
   @UI.hidden:true 
   a._BusinessPartner.DataController9,
   @Consumption.hidden:true
   @UI.hidden:true
   a._BusinessPartner.DataController10
 }
 
where WorkAgreementStatus = '1'




/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_BUSINESSUSER",
"I_PERSONWORKAGREEMENT_1",
"I_PERSONWORKAGRMTSTATUS",
"I_WORKFORCEPERSON"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/