I_WorkforceAssignmentDetails

@AbapCatalog.sqlViewName: 'IWRKFCASSGMTDETS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC
}
@ObjectModel: {
   semanticKey: ['WorkforceAssignment', 'WorkforceAssgmtStartDate'],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #M
   }
}
@EndUserText.label: 'Workforce Assignment Details'
define view I_WorkforceAssignmentDetails
  as select from wfd_d_assgmtdets
  association [1..1] to I_WorkforceAssignment        as _WorkforceAssignment       on  $projection.WorkforceAssignment = _WorkforceAssignment.WorkforceAssignment
  association [0..1] to I_WorkforceAssignmentStatus  as _WorkforceAssignmentStatus on  $projection.WorkforceAssignmentStatus = _WorkforceAssignmentStatus.WorkforceAssignmentStatus
  association [1]    to I_CompanyCode                as _CompanyCode   on $projection.CompanyCode  = _CompanyCode.CompanyCode
  association [1]    to I_CostCenter  as _CostCenter on  $projection.CostCenter  = _CostCenter.CostCenter
                                                    and $projection.CompanyCode     = _CostCenter.CompanyCode
                                                    and _CostCenter.ValidityStartDate   <= $projection.WorkforceAssgmtEndDate
                                                    and _CostCenter.ValidityEndDate     >= $projection.WorkforceAssgmtEndDate
  association [1]    to E_WorkforceAssignmentDetails as _Extension                 on  $projection.WorkforceAssignment      = _Extension.WorkforceAssignment
                                                                                   and $projection.WorkforceAssgmtStartDate = _Extension.WorkforceAssgmtStartDate
{
  key workforce_assgmt_id            as WorkforceAssignment,
  key start_date                     as WorkforceAssgmtStartDate,
      end_date                       as WorkforceAssgmtEndDate,
      @ObjectModel.foreignKey.association: '_WorkforceAssignmentStatus'
      employment_status              as WorkforceAssignmentStatus,
      employment_percent             as EmploymentPercent,
      company_code                   as CompanyCode,
      cost_center                    as CostCenter,
      controlling_area               as ControllingArea,
      weekly_working_hours           as WeeklyWorkingHours,
      weekly_working_days            as WeeklyWorkingDays,
      job_title                      as WorkforcePersonJobTitle,
      job_code                       as WorkforcePersonJobCode,
      manager_work_assgmt            as ManagerAssignmentID,
      country                        as Country2DigitISOCode,
      manager_work_assignment_ext_id as ManagerAssignmentExternalID,
      main_employment_indicator      as WorkforceAssignmentIsPrimary,
//      _CompanyCode.CompanyCodeName  as CompanyCodeName,

      _CompanyCode,
//      _CostCenter._Text[1: Language = $session.system_language ].CostCenterName  as CostCenterName, 

      _CostCenter,
//      _WorkforceAssignmentStatus._Text[1: Language = $session.system_language ].AssignmentStatusText as AssignmentStatusText,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                      #TO_COMPOSITION_ROOT]
      _WorkforceAssignment,
      _WorkforceAssignmentStatus
}  
where
//      company_code is not initial and   

  block_ind    = ' ' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"WFD_D_ASSGMTDETS"
],
"ASSOCIATED":
[
"E_WORKFORCEASSIGNMENTDETAILS",
"I_COMPANYCODE",
"I_COSTCENTER",
"I_WORKFORCEASSIGNMENT",
"I_WORKFORCEASSIGNMENTSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/