I_WorkflowTaskDueDate

@AbapCatalog : {
  sqlViewName: 'IWFTASKDUEDATE',
  buffering.type: #NONE
}
@EndUserText.label: 'Workflow work item due dates'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType : {
  dataClass: #CUSTOMIZING,
  serviceQuality: #A,
  sizeCategory: #M
}
define view I_WorkflowTaskDueDate
// classic workflow uses table SWWWIDEADL to store dedline data 

  as select from swwwideadl

{
  key wi_id                                                                 as WorkflowTaskInternalID,
      case wi_ds_utc
        when 'X' then cast( dats_tims_to_tstmp(wi_dsd, wi_dst, 'UTC', $session.client, 'INITIAL') as swfdsutcdatetime )
        else cast ( '0' as swfdsutcdatetime )
      end                                                                   as WrkflwTskDesiredStartUTCDteTme,
      case wi_le_utc
        when 'X' then cast( dats_tims_to_tstmp(wi_led, wi_let, 'UTC', $session.client, 'INITIAL') as swfleutcdatetime )
        else cast ( '0' as swfleutcdatetime )
      end                                                                   as WorkflowTaskDueUTCDateTime

}

union
// flexible workflow uses SWWFLEXDL to store deadlines, but there a morde than one deadline actions.

// due data & time is assigned to action "markStepAsOverdue". Other actions are not considered.

// desired start is not supported here.  

select from        swwflexdl
  inner join       swwflexdla on  ( swwflexdl.wi_id       = swwflexdla.wi_id 
                              and   swwflexdl.deadline_nr = swwflexdla.deadline_nr )
  {
   key swwflexdl.wi_id                                                      as WorkflowTaskInternalID,
       cast ( '0' as swfdsutcdatetime )                                     as WrkflwTskDesiredStartUTCDteTme, 
       swwflexdl.deadline_tmstmp                                            as WorkflowTaskDueUTCDateTime
  }                            
where swwflexdla.action = 'markStepAsOverdue'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SWWFLEXDL",
"SWWFLEXDLA",
"SWWWIDEADL"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/