I_WorkPermitPartner

@AbapCatalog.sqlViewName: 'IPERMITPARTNER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Permit Partner'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #S, dataClass: #META}
@VDM.viewType: #BASIC
define view I_WorkPermitPartner
  as select from ihpa  as _Partner
    inner join   wcaap as _WorkPermit on _Partner.objnr = _WorkPermit.objnr
  association [1..1] to I_Customer        as _Customer        on _Customer.Customer = $projection.Partner
  association [1..1] to I_PartnerFunction as _PartnerFunction on _PartnerFunction.PartnerFunction = $projection.PartnerFunction
{
  key _Partner.objnr                         as MaintObjectInternalID,
      @ObjectModel.foreignKey.association: '_PartnerFunction'
  key cast(_Partner.parvw as parvw_unv)      as PartnerFunction,
  key _Partner.counter                       as MaintenancePartnerObjectNumber,
      _Partner.obtyp                         as MaintObjectCategory,
//      @API.element.successor: 'MaintenancePartner'

//      @API.element.releaseState: #DEPRECATED

//      cast(_Partner.parnr  as abap.char( 10 ) )  as MaintenancePartner,

      _Partner.parnr                         as MaintenancePartner,
      _WorkPermit.wapinr                     as WorkPermit,
      _WorkPermit.iwerk                      as MaintenancePlanningPlant,
      _WorkPermit.wapiuse                    as WorkPermitType,
      _Partner.ernam                         as CreatedByUser,
      _Partner.erdat                         as CreationDate,
      _Partner.erzeit                        as CreationTime,
      _Partner.aenam                         as LastChangedByUser,
      _Partner.aezeit                        as LastChangeTime,
      _Partner.aedat                         as LastChangeDate,
      lpad(ltrim(_Partner.parnr,'0'),10,'0') as Partner,
      _PartnerFunction,
      _Customer
}
where
      _Partner.kzloesch = ' '
  and _Partner.objnr != ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"IHPA",
"WCAAP"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_PARTNERFUNCTION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/