I_WorkPermitApproval

@AbapCatalog.sqlViewName: 'IWPMAPPROVAL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Approvals on Work Permit Object'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass:  #CUSTOMIZING
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_WorkPermitApproval
  as select distinct from wcagn
    inner join            wcaap as _WorkPermitAppl on wcagn.objnr = _WorkPermitAppl.objnr
  association [0..1] to t357g_t                   as _PermitTxt       on  $projection.WorkPermitApproval = _PermitTxt.pmsog
                                                                      and _PermitTxt.spras               = $session.system_language
  association [0..1] to I_WorkPermitApprovalBasic as _ApprovalDetails on  $projection.WorkPermitApproval              = _ApprovalDetails.WorkPermitApproval
                                                                      and $projection.WorkPermitType                  = _ApprovalDetails.WorkPermitType
                                                                      and $projection.MaintenancePlanningPlant        = _ApprovalDetails.MaintenancePlanningPlant
                                                                      and _ApprovalDetails.WorkPermitApprovalScenario = '1'
{
  key wcagn.objnr                     as WorkPermitInternalID,
  key wcagn.counter                   as NumberOfWrkPermitApprovals,
      _WorkPermitAppl.wapinr          as WorkPermit,
      wcagn.pmsog                     as WorkPermitApproval,
      wcagn.kzltx                     as WorkPermitHasLongText,
      wcagn.erdat                     as CreationDate,
      wcagn.ernam                     as CreatedByUser,
      wcagn.aedat                     as LastChangedDate,
      wcagn.aenam                     as LastChangedByUser,
      wcagn.workpermitapprovalstatus  as WorkPermitApprovalStatus,
      _PermitTxt.gntxt                as WorkPermitApprovalDescription,
      _WorkPermitAppl.wapityp         as WrkPmtMgmtObjSubType,
      _WorkPermitAppl.iwerk           as MaintenancePlanningPlant,
      _WorkPermitAppl.wapiuse         as WorkPermitType,
      wcagn.workpermitapprovalcomment as WorkPermitApprovalComment,
      case  wcagn.kzltx
      when 'X' then cast(concat(wcagn.objnr, wcagn.counter) as tdobname)
      else '' end                     as TextObjectKey,
      _ApprovalDetails
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T357G_T",
"WCAAP",
"WCAGN"
],
"ASSOCIATED":
[
"I_WORKPERMITAPPROVALBASIC",
"T357G_T"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/