I_WorkCenterGrpByAreaOfRespy

@AbapCatalog.sqlViewName: 'IWKCGPAOR'
@AbapCatalog.compiler.compareFilter: true
//@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}

@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'WorkCenterGroupInternalID'
@ObjectModel.semanticKey: ['Plant', 'WorkCenterGroupInternalID']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@Search.searchable: true
@EndUserText.label: 'Work Center Group for AOR'

define view I_WorkCenterGrpByAreaOfRespy

  as select from I_WorkCenterHierHeader as CRHH
  association [0..*] to I_WorkCenterGroupText        as _Text               on  $projection.WorkCenterGroupTypeCode   = _Text.WorkCenterGroupTypeCode
                                                                            and $projection.WorkCenterGroupInternalID = _Text.WorkCenterGroupInternalID
  association [0..1] to I_WorkCenterGroupTypeText    as _WorkCenterTypeText on  $projection.WorkCenterGroupType = _WorkCenterTypeText.WorkCenterGroupType
  association [0..1] to I_User                       as _User               on  $projection.UserID = _User.UserID
  association [1..1] to I_ProductionResourceType as _ProductionResourceType on $projection.WorkCenterGroupTypeCode = _ProductionResourceType.ProductionResourceType
  association [0..1] to I_WorkCtrGrpCapByAreaOfRespy as _Wrkcntrgrpaor      on  $projection.Plant                      = _Wrkcntrgrpaor.Plant
                                                                            and _Wrkcntrgrpaor.UserID                  = $session.user
                                                                            and $projection.WorkCenterGroupInternalID  = _Wrkcntrgrpaor.WorkCenterGroupInternalID
                                                                            and _Wrkcntrgrpaor.WorkCenterGroupTypeCode = 'G'
  association [1..1] to I_Plant                      as _Plant              on  $projection.Plant = _Plant.Plant
{
      // Key


      //@ObjectModel.text.element: 'MRPControllerName'

      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key CRHH.WrkCtrHierObjID                                                    as WorkCenterGroupInternalID,
      @ObjectModel.foreignKey.association: '_ProductionResourceType'
  key CRHH.WrkCtrHierObjType                                                  as WorkCenterGroupTypeCode,
      CRHH.WrkCtrHierName                                                     as WorkCenterGroup,
      @Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
      CRHH.WrkCtrHierPlant                                                    as Plant,
      // Attributes

      _Text[1:Language = $session.system_language].WorkCenterGroupDescription as WorkCenterGroupDescription,


      CRHH.WorkCenterGroupType                                                as WorkCenterGroupType,

      _WorkCenterTypeText[1:Language = $session.system_language].WorkCenterGroupTypeDescription,

      CRHH.IsDeleted                                                          as IsDeleted,
      _Wrkcntrgrpaor.UserID                                                   as UserID,
      $session.user                                                           as UserName,

      _Text,

      _User,
      _Plant,
      _ProductionResourceType
}
where
      WrkCtrHierObjType = 'G'
  and IsDeleted != 'X';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKCENTERGROUPTEXT",
"I_WORKCENTERGROUPTYPETEXT",
"I_WORKCENTERHIERHEADER",
"I_WORKCTRGRPCAPBYAREAOFRESPY"
],
"ASSOCIATED":
[
"I_PLANT",
"I_PRODUCTIONRESOURCETYPE",
"I_USER",
"I_WORKCENTERGROUPTEXT",
"I_WORKCENTERGROUPTYPETEXT",
"I_WORKCTRGRPCAPBYAREAOFRESPY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/