I_WorkCenterAOR

DDL: I_WORKCENTERAOR Type: view_entity COMPOSITE

Work Center Area of Responsibility

I_WorkCenterAOR is a Composite CDS View that provides data about "Work Center Area of Responsibility" in SAP S/4HANA. It reads from 1 data source (I_WorkCenterBySemanticKey) and exposes 9 fields with key fields WorkCenter, Plant. It has 3 associations to related views.

1 data source(s) 9 fields

Data Sources (1)

SourceAliasJoin Type
I_WorkCenterBySemanticKey I_WorkCenterBySemanticKey from

Associations (3)

CardinalityTargetAliasCondition
[0..1] I_WorkCenterText _WorkCenterText $projection.WorkCenterInternalID = _WorkCenterText.WorkCenterInternalID and _WorkCenterText.Language = $session.system_language and _WorkCenterText.WorkCenterTypeCode = 'A'
[1..1] I_WorkCenterBySemanticKey _WorkCenter $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID and $projection.Plant = _WorkCenter.Plant
[0..1] I_PPAreaOfResponsibility _SDMAOR $projection.Plant = _SDMAOR.Plant and _SDMAOR.UserID = $session.user and _SDMAOR.ProductionSupervisor is initial and $projection.WorkCenterInternalID = _SDMAOR.WorkCenterInternalID

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Work Center Area of Responsibility view
Search.searchable true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #CUSTOMIZING view
VDM.viewType #COMPOSITE view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY WorkCenter WorkCenter
KEY Plant Plant
PlantName _Plant PlantName
WorkCenterInternalID WorkCenterInternalID
WorkCenterText _WorkCenterText WorkCenterText
UserID _SDMAOR UserID
UserName
_WorkCenter _WorkCenter
_Plant _Plant 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Center Area of Responsibility'
@Search.searchable: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #S, dataClass: #CUSTOMIZING}
@VDM.viewType:       #COMPOSITE

define root view entity I_WorkCenterAOR 
   as select from I_WorkCenterBySemanticKey
  association [0..1] to I_WorkCenterText as _WorkCenterText on  $projection.WorkCenterInternalID = _WorkCenterText.WorkCenterInternalID
                                                            and _WorkCenterText.Language         = $session.system_language
                                                            and _WorkCenterText.WorkCenterTypeCode = 'A'
  association [1..1] to I_WorkCenterBySemanticKey as _WorkCenter on $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
                                                            and $projection.Plant = _WorkCenter.Plant
  association [0..1] to I_PPAreaOfResponsibility     as _SDMAOR                      on $projection.Plant           = _SDMAOR.Plant 
                                                                                      and  _SDMAOR.UserID = $session.user
                                                                                      and  _SDMAOR.ProductionSupervisor is initial
                                                                                      and $projection.WorkCenterInternalID =  _SDMAOR.WorkCenterInternalID
{

      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8}
      @ObjectModel.text.element: ['WorkCenterText']
  key WorkCenter,
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8}
      @ObjectModel.text.element: ['PlantName']
      @ObjectModel.foreignKey.association: '_Plant'
  key Plant,
      @Semantics.text: true
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8}
      _Plant.PlantName,

      // Internal Key

      WorkCenterInternalID,
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      _WorkCenterText.WorkCenterText,
      
      _SDMAOR.UserID as UserID,
      $session.user  as UserName,
      
      _WorkCenter,
      _Plant
} 
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"I_PPAREAOFRESPONSIBILITY",
"I_WORKCENTERBYSEMANTICKEY",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"I_PLANT",
"I_WORKCENTERBYSEMANTICKEY"
],
"BASE":
[
"I_WORKCENTERBYSEMANTICKEY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More