I_WorkAssgmtDetsDEX

@AccessControl.authorizationCheck:#MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType: #BASIC

@Analytics.dataExtraction: {
            enabled: true,
            delta.changeDataCapture:
    {

            mapping:[
               {
                    table: 'wfd_d_assgmtdets', role: #MAIN,
                    viewElement: ['WorkAssignment','WorkAssignmentStartDate'],
                    tableElement: ['workforce_assgmt_id','start_date']
                },
                  {
                    table: 'wfd_d_keymap', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['WorkAssignment'],
                    tableElement: ['workforce_assgmt_id']
                }
            ]
        }
    }

@ObjectModel.supportedCapabilities:[ #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.sapObjectNodeType.name:'WorkAssignmentDetails'

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Workforce Person Assignment Details'

define view entity I_WorkAssgmtDetsDEX
  as select from wfd_d_assgmtdets as assgmtdets
    inner join   wfd_d_keymap     as keymap on keymap.workforce_assgmt_id = assgmtdets.workforce_assgmt_id
 
  association [1] to I_WorkforcePersonDEX as _WorkforcePerson on $projection.BusinessPartner = _WorkforcePerson.BusinessPartner
  association [1] to I_CompanyCode        as _CompanyCode     on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1] to I_CostCenter         as _CostCenter      on $projection.CostCenter = _CostCenter.CostCenter

{
  key assgmtdets.workforce_assgmt_id            as WorkAssignment,
  key assgmtdets.start_date                     as WorkAssignmentStartDate,

      assgmtdets.end_date                       as WorkAssignmentEndDate,
      keymap.person_id_external                 as WorkforcePersonExternalID,
      keymap.business_partner_id                as BusinessPartner,
      
      @Semantics.booleanIndicator: true
      assgmtdets.main_employment_indicator      as WorkAssignmentIsPrimary,

      keymap.user_id                            as WorkAssignmentExternalID,

      assgmtdets.manager_work_assgmt            as SupervisorWorkAssignmentID,
      assgmtdets.manager_work_assignment_ext_id as SupervisorWorkAssignmentExtID,
      assgmtdets.job_title                      as WorkforcePersonJobTitle,
      assgmtdets.job_code                       as WorkforcePersonJobCode,
      assgmtdets.weekly_working_hours           as WorkingHoursPerWeek,
     
      assgmtdets.employment_percent             as EmploymentPercent, 
      assgmtdets.weekly_working_days            as WorkingDaysPerWeek,
      @Semantics.booleanIndicator: true
      assgmtdets.employment_status              as WorkAssignmentStatus,
      assgmtdets.company_code                   as CompanyCode,
      assgmtdets.cost_center                    as CostCenter,
      cast( assgmtdets.country as land1  )      as CountryOrRegion,
      _WorkforcePerson,
      _CompanyCode,
      _CostCenter

}
where keymap.block_ind        =  ''
  and assgmtdets.block_ind    =  ''
  and assgmtdets.company_code <> ''   //To filter the technically inactive records

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"WFD_D_ASSGMTDETS",
"WFD_D_KEYMAP"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_COSTCENTER",
"I_WORKFORCEPERSONDEX"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/