I_WBSElementWithCodingMaskVH

@AbapCatalog.sqlViewName: 'IWBSWITHCMASKVH'
@EndUserText.label: 'Value help for WBS Element with coding mask'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.representativeKey: 'WBSElement'
@ObjectModel.dataCategory: #VALUE_HELP
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
@Search.searchable: true
@Consumption.ranked: true

define view I_WBSElementWithCodingMaskVH
  as select from I_WBSElement as WBSElement
{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key WBSElement.WBSElementWithCodingMask      as WBSElement,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      WBSElement.WBSDescription                as WBSDescription,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @EndUserText.label: 'WBS Element Language-Dependent Short Text'
      WBSElement._WBSElementShortText.LanguageBasedShortText as WBSElementLangBsdDescription,
      //WBSElement._Project.Project              as Project,

      WBSElement._Project.ProjectWithCodingMask as Project,
      WBSElement._Project.ProjectDescription   as ProjectDescription,
      WBSElement.ResponsiblePerson             as ResponsiblePerson,
      WBSElement.ResponsiblePersonName         as ResponsiblePersonName,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSElement.WBSElementIsBillingElement    as WBSElementIsBillingElement,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSElement.WBSIsAccountAssignmentElement as WBSIsAccountAssignmentElement,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSElement.WBSElementIsPlanningElement   as WBSElementIsPlanningElement,

      //Following fields used for authorization using DCL

      @UI:{ hidden: true }
      WBSElement.ProjectType                   as ProjectType,
      @UI:{ hidden: true }
      WBSElement.ControllingArea               as ControllingArea,
      @UI:{ hidden: true }
      WBSElement.RespCostCenterControllingArea as RespCostCenterControllingArea,
      @UI:{ hidden: true }
      WBSElement.ResponsibleCostCenter         as ResponsibleCostCenter,
      @UI:{ hidden: true }
      WBSElement.ProfitCenter                  as ProfitCenter,
      @UI:{ hidden: true }
      WBSElement.FreeDefinedAttribute01        as FreeDefinedAttribute01,
      @UI:{ hidden: true }
      WBSElement.FreeDefinedAttribute02        as FreeDefinedAttribute02,
      @UI:{ hidden: true }
      WBSElement.FreeDefinedAttribute03        as FreeDefinedAttribute03,
      @UI:{ hidden: true }
      WBSElement.FreeDefinedAttribute04        as FreeDefinedAttribute04,
      @UI:{ hidden: true }
      WBSElement.FreeDefinedIndicator1         as FreeDefinedIndicator1,
      @UI:{ hidden: true }
      WBSElement.FreeDefinedIndicator2         as FreeDefinedIndicator2,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      WBSElement._ResponsiblePerson,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      WBSElement.ApplicantCode                 as ApplicantCode,
      @UI:{ hidden: true }
      WBSElement.WBSElementObject              as WBSElementObject,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      WBSElement._ProjectApplicant
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTBYINTERNALKEY",
"I_PROJECTOBJECTSHORTTEXT",
"I_WBSELEMENT"
],
"ASSOCIATED":
[
"I_PROJECTAPPLICANT",
"I_PROJECTRESPONSIBLEPERSON"
],
"BASE":
[
"I_WBSELEMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/