I_WBSElementDataStdVH

@AbapCatalog.sqlViewName: 'IWBSDATSTDVH'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.representativeKey: 'WBSElementInternalID'
@ObjectModel.dataCategory: #VALUE_HELP
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
@Search.searchable: true
@EndUserText.label: 'WBSElement Data'
define view I_WBSElementDataStdVH
  as select from I_WBSElementData_2
  // Person in Responsible for Project

  association [0..1] to I_ProjectResponsiblePerson as _ResponsiblePerson on $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  // Project Applicant

  association [0..1] to I_ProjectApplicant         as _ProjectApplicant  on $projection.ApplicantCode = _ProjectApplicant.ApplicantCode

{
      //      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}

      @UI.hidden: true
  key WBSElementInternalID          as WBSElementInternalID,
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      WBSElementExternalID          as WBSElementExternalID,
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      WBSDescription                as WBSDescription,
      _Project.ProjectExternalID    as ProjectExternalID,
      _Project.ProjectDescription   as ProjectDescription,
      ResponsiblePerson             as ResponsiblePerson,
      ResponsiblePersonName         as ResponsiblePersonName,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSElementIsBillingElement    as WBSElementIsBillingElement,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSIsAccountAssignmentElement as WBSIsAccountAssignmentElement,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSElementIsPlanningElement   as WBSElementIsPlanningElement,

      //Following fields used for authorization using DCL

      @UI:{ hidden: true }
      ProjectType                   as ProjectType,
      @UI:{ hidden: true }
      ControllingArea               as ControllingArea,
      @UI:{ hidden: true }
      RespCostCenterControllingArea as RespCostCenterControllingArea,
      @UI:{ hidden: true }
      ResponsibleCostCenter         as ResponsibleCostCenter,
      @UI:{ hidden: true }
      ProfitCenter                  as ProfitCenter,
      @UI:{ hidden: true }
      FreeDefinedAttribute01        as FreeDefinedAttribute01,
      @UI:{ hidden: true }
      FreeDefinedAttribute02        as FreeDefinedAttribute02,
      @UI:{ hidden: true }
      FreeDefinedAttribute03        as FreeDefinedAttribute03,
      @UI:{ hidden: true }
      FreeDefinedAttribute04        as FreeDefinedAttribute04,
      @UI:{ hidden: true }
      FreeDefinedIndicator1         as FreeDefinedIndicator1,
      @UI:{ hidden: true }
      FreeDefinedIndicator2         as FreeDefinedIndicator2,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      _ResponsiblePerson,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      ApplicantCode                 as ApplicantCode,
      @UI:{ hidden: true }
      WBSElementObject              as WBSElementObject,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      _ProjectApplicant
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTDATA_2",
"I_WBSELEMENTDATA_2"
],
"ASSOCIATED":
[
"I_PROJECTAPPLICANT",
"I_PROJECTRESPONSIBLEPERSON"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/