I_VisualLocations

@AbapCatalog.sqlViewName: 'IVISUALLOC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Location Master Data'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.type      : #INHERITED
@ClientHandling.algorithm : #SESSION_VARIABLE

define view I_VisualLocations as select  distinct from t001k as c 
  left outer join t001w     as p  on ( p.bwkey = c.bwkey )
  left outer join v_oijrra  as l  on ( l.werk = p.werks and l.rpart = 'LG' )
  left outer join v_oifspbl as b  on ( b.pblnr = l.locid  or b.pblnr = lpad(l.locid,10,'0') ) //Note 2844273

  left outer join adrc      as a  on (b.addrnum =  a.addrnumber )
  left outer join v_t005u   as t  on (a.region = t.bland and a.country = t.land1 and t.spras = $session.system_language )
  left outer join v_t005t   as tc on ( a.country = tc.land1 and tc.spras = $session.system_language )
  { 
  key c.bukrs                      as CompanyCode , 
  key p.werks                      as Plant ,
  key l.locid                      as LocationId , 
      l.rpart                      as BusinessPartnerRoleType,
      b.name1                      as BusinessEntityLocationName ,
      b.pbltyp                     as LocationType, 
      a.addrnumber                 as AddressNumber, 
      a.city1                      as CityName, 
      tc.landx50                   as CountryName ,
      t.bezei                      as Region,
      a.post_code1                 as PostalCode,
      cast( ' ' as abap.char(20))  as Latitude,
      cast( ' ' as abap.char(20))  as Longitude,
      cast( ' ' as abap.char(1 ))  as IsBerthManaged,
      cast( ' ' as abap.char(10))  as TankID 
  } 
  where l.delind  = ' ' 
  and   a.city1   is not null
  and   a.country is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ADRC",
"T001K",
"T001W",
"V_OIFSPBL",
"V_OIJRRA",
"V_T005T",
"V_T005U"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/