I_VisualAnalysis

@AbapCatalog.sqlViewName: 'IVISUALANALYSIS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType:  #COMPOSITE
@Search.searchable:false
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Visual Analysis'
define view I_VisualAnalysis as select distinct from I_NominationAnalysisPath as nom
left outer join mara                    as  a  on nom.ScheduledMaterial  = a.matnr
left outer join I_Oij06_Myeventss1_Main as ev  on ev.NominationDoc       = nom.NominationDoc
                                                   and ev.NominationDocItem   = nom.NominationDocItem
                                                   and ev.NominationEventType = 'ETA'  //Qty Alerts needed all type of events

left outer join I_OilPartnerRoles as b on (b.LocationId = nom.LocationId and b.OilPartnerRoleType = 'LG')
left outer join t001w  as c on (b.Plant = c.werks)
left outer join I_Purreqvaluationarea  as d on (c.bwkey = d.ValuationArea)
left outer join I_NominationModeOfTranspVH  as e on e.ModeOfTransport  = nom.NominationModeOfTransport
inner join I_CalendarDate as calDate on calDate.CalendarDate = nom.NominationScheduleDate

  association [0..1] to I_Supplier as _Shipper                  on  $projection.NominationShipper   = _Shipper.Supplier
  association [0..1] to I_Supplier as _Carrier                  on  $projection.NominationCarrier   = _Carrier.Supplier
  association [0..1] to I_Supplier as _Inspector                on  $projection.NominationInspector = _Inspector.Supplier
  association [0..1] to I_Supplier as _ImportExportPartner      on  $projection.ImportExportPartner = _ImportExportPartner.Supplier
  association [0..1] to I_Supplier as _ConsigneePartnerVendor   on  $projection.ConsigneePartner    = _ConsigneePartnerVendor.Supplier
  association [0..1] to I_Customer as _ConsigneePartnerCustomer on  $projection.ConsigneePartner    = _ConsigneePartnerCustomer.Customer
  association [0..1] to I_Supplier as _ContractPartnerVendor    on  $projection.ContractPartner     = _ContractPartnerVendor.Supplier
  association [0..1] to I_Customer as _ContractPartnerCustomer  on  $projection.ContractPartner     = _ContractPartnerCustomer.Customer
  association [0..1] to I_Supplier as _LocationPartnerVendor    on  $projection.LocationPartner     = _LocationPartnerVendor.Supplier
  association [0..1] to I_Customer as _LocationPartnerCustomer  on  $projection.LocationPartner     = _LocationPartnerCustomer.Customer
  
 {
  key nom.NominationDoc,
  key nom.NominationDocItem,
  cast('' as abap.char(10))                   as NominationDocDischargeItem,
  cast('' as char10)                          as IsNominationDocItem,
  cast('' as char2)                           as IsLoad,
  nom.ScheduledMaterial,
  //d.bukrs   as CompanyCode,

  d.CompanyCode,
  nom.NominationCarrier,
  nom.NominationModeOfTransport,
  e.ModeOfTransportDesc                       as ModeOfTransportText,
  nom.LocationId,
  nom.VehicleId,
 // cast ('' as abap.char(10) )               as DischargeVehicleId,

  nom.ShippingRoute,
 // cast('' as abap.char(6))                  as DischargeShippingRoute,

  cast('' as abap.char(10) )                as DestinationLocation,
  a.matkl                                   as MaterialGroup,
  nom.TransportSystem,
  nom.NominationScheduleType,
  nom.IsBookedTransportSystem,
  nom.IsReferenceDocument,
  nom.NominationReferenceDocument,
  nom.NominationItemStatus,
  nom.NominationScheduleDate,
  calDate.YearWeek     as NominationCalendarWeek,
  calDate.YearMonth    as NominationCalendarMonth,
  calDate.CalendarYear as NominationCalendarYear,
  nom.ScheduledBatchStartDateTime,
  cast(0 as abap.quan( 13, 3 ))             as ActualDischargeQuantity,
  cast( 0 as abap.dec( 13, 3 ))             as TransitTime,
  ev.ActualStartDateFrom,
  ev.ActualStartTimeFrom,
  cast('' as abap.char(19) )                as DischargeBatchStartDateTime,//Discharge Time Stamp

  cast('00000000' as abap.dats)             as DischargeDate,          //Actual Discharge Date

  cast('000000' as abap.tims)               as DischargeTime,          //Actual Discharge Time

  cast( 0 as abap.dec( 13, 3 ))             as DeltaLoadDischargeTime,
  cast( 0 as abap.dec( 13, 3 ))             as NominationOverallLoad,
  cast( 0 as abap.dec( 13, 3 ))             as NominationOvrlDischarge,
  nom.ScheduledQuantity,
  nom.ScheduledQuantityUnit,
  nom.ActualScheduledQuantity,
  nom.ActualScheduledQuantityUnit,
  cast(0  as abap.quan( 13, 3 ))            as DeltaLoadQuantity,
  cast(0  as abap.quan( 13, 3 ))            as DeltaDischargeQuantity,
  cast('' as char2)                         as NominationDocItmIndicator,
  cast('' as char15)                        as DeltaText,
  cast('' as char15)                        as DeltaDischargeText,
  
  nom.VehicleIsBlocked,
  nom.NominationShipper,
  nom.NominationInspector,
  nom.ImportExportPartner,
  nom.ConsigneePartner,
  nom.ContractPartner,
  nom.LocationPartner,
  
  _Shipper,                                                             
  _Carrier,
  _Inspector,
  _ImportExportPartner,
  _ConsigneePartnerVendor,
  _ConsigneePartnerCustomer,
  _ContractPartnerVendor,
  _ContractPartnerCustomer,
  _LocationPartnerVendor,
  _LocationPartnerCustomer
  
 }
  where  nom.NominationHeaderStatus = '3'
     and nom.NominationIsMarkedForDeletion != 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARDATE",
"I_NOMINATIONANALYSISPATH",
"I_NOMINATIONMODEOFTRANSPVH",
"I_OIJ06_MYEVENTSS1_MAIN",
"I_OILPARTNERROLES",
"I_PURREQVALUATIONAREA",
"MARA",
"T001W"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/