I_VarianceReasonText

@AbapCatalog.sqlViewName: 'IVARCREASONTEXT'
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'VarianceReasonCode'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Variance Reason - Text'

define view I_VarianceReasonText
  as select from trugt as txt
  association [1..1] to I_Plant          as _Plant          on  $projection.Plant = _Plant.Plant
  association [1..1] to I_Language       as _Language       on  $projection.Language = _Language.Language
  association [1..1] to I_VarianceReason as _VarianceReason on  $projection.Plant              = _VarianceReason.Plant
                                                            and $projection.VarianceReasonCode = _VarianceReason.VarianceReasonCode
{
      @ObjectModel.foreignKey.association: '_VarianceReason'
      @ObjectModel.text.element: ['VarianceReasonName']
  key cast(txt.grund as pph_agrnd preserving type) as VarianceReasonCode,
      @ObjectModel.foreignKey.association: '_Plant'
      @ObjectModel.sapObjectNodeTypeReference: 'Plant'
  key txt.werks                                    as Plant,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast(txt.spras as spras preserving type)     as Language,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(txt.grdtx as pph_grdtx preserving type) as VarianceReasonName,

      // Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT] 
      _VarianceReason,
      _Plant,
      _Language
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TRUGT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PLANT",
"I_VARIANCEREASON"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/