I_UtilsProdAttributes

@AbapCatalog.sqlViewName: 'IUILPRATTR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'IS-U Product Attributes'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_UtilsProdAttributes
  as select distinct from I_UtilsProdChar           as _M
    left outer join       I_ProductsUtilsAttributes as _P on(
      _P.UtilitiesReferenceProduct = _M.UtilitiesReferenceProduct
      or _P.UtilitiesProduct       = _M.UtilitiesReferenceProduct
    )

    left outer join       I_UtilsProdCharValue      as _C on(
      _C.ClfnObjectID       = _P.UtilitiesProduct
      and _C.Characteristic = _M.Characteristic
    )
    left outer join       I_ClfnCharcBasic          as _I on(
      _M.Characteristic = _I.Characteristic
    )
  association [0..1] to I_UtilsProdCharValue as _TS on  $projection.UtilsTimeSliceCharacteristicID = _TS.Characteristic
                                                    and $projection.UtilitiesProduct               = _TS.ClfnObjectID
{
  key _P.UtilitiesProduct       as UtilitiesProduct,
  key _M.Characteristic,
      _P.UtilitiesReferenceProduct,
      _C.CharcValuePositionNumber,
      _M.UtilsSemanticsType,
      _M.UtilsSemanticsName1,
      _M.UtilsSemanticsName2,
      _M.UtilsBillingOperand,
      _M._UtilsOperand.UtilsOperandCategory,
      _M.UtilsTimeSliceCharacteristicID,
      _C.CharcValue,
      _C.CharcValueUnit,
      _M._UtilsOperand,
      _C.ValidityEndDate,
      _C.ValidityStartDate,
      _I.CharcInternalID,
      @Consumption.hidden
      _P.ProductType,
      _P.ProductGroup,
      @Consumption.hidden
      _P.ProductAuthorizationGroup,
      _I.CharcDataType,
      _C.CharcToAmount,
      _C.CharcFromAmount,
      _TS.CharcFromDecimalValue as UtilsTimeSliceDurationFrom,
      _TS.CharcToDecimalValue   as UtilsTimeSliceDurationTo,
      _TS.CharcValueUnit        as UtilsTimeSliceDurationUoM,
      case when _C.Currency is null
       then _I.Currency
       else _C.Currency
      end                       as Currency,
      _C.CharcToDate,
      _C.CharcFromDate,
      _C.CharcToDecimalValue,
      _C.CharcFromDecimalValue,
      _I.CharcDecimals,
      _I.CharcCheckTable,
      _I.CharcReferenceTable,
      _I.CharcReferenceTableField,
      _I.CharcConversionRoutine,
      _I.CharcLength,
      _P._ProductType,
      _P._ProductGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CLFNCHARCBASIC",
"I_PRODUCTSUTILSATTRIBUTES",
"I_UTILSOPERAND",
"I_UTILSPRODCHAR",
"I_UTILSPRODCHARVALUE"
],
"ASSOCIATED":
[
"I_PRODUCTGROUP",
"I_PRODUCTTYPE",
"I_UTILSOPERAND",
"I_UTILSPRODCHARVALUE"
],
"BASE":
[
"I_PRODUCTSUTILSATTRIBUTES",
"I_UTILSPRODCHAR"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/