I_UsgeDcsnSelectedSetCodeGrp

@AbapCatalog.sqlViewName: 'IUDSELSETCDGRP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Code Group of Selected Set for UD'
@AccessControl.authorizationCheck: #MANDATORY
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.usageType: {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #A
}
@ObjectModel.representativeKey: 'UsageDecisionCodeGroup'
@Metadata.ignorePropagatedAnnotations: true

define view I_UsgeDcsnSelectedSetCodeGrp 
  as select distinct from qpac
    inner join qpgr
       on  qpgr.katalogart = '3' // Usage Decision

       and qpgr.codegruppe = qpac.codegruppe

   association [0..1] to I_Plant as _SelectedCodeSetPlant
      on $projection.SelectedCodeSetPlant = _SelectedCodeSetPlant.Plant

   association [0..1] to I_InspUsgeDcsnSelectedSet as _SelectedCodeSet
      on  _SelectedCodeSet.SelectedCodeSetPlant = $projection.SelectedCodeSetPlant 
      and _SelectedCodeSet.SelectedCodeSet      = $projection.SelectedCodeSet

   association [0..1] to I_UsageDcsnSelectedCodeSet as _UsageDcsnSelectedCodeSet
      on  _UsageDcsnSelectedCodeSet.SelectedCodeSetPlant = $projection.SelectedCodeSetPlant 
      and _UsageDcsnSelectedCodeSet.SelectedCodeSet      = $projection.SelectedCodeSet
      
   association [0..1] to I_UsageDecisionCodeGroup as _UsageDecisionCodeGroup
      on $projection.UsageDecisionCodeGroup = _UsageDecisionCodeGroup.UsageDecisionCodeGroup
      
   association [0..*] to I_UsgeDcsnSelectedSetCode as _UsgeDcsnSelectedSetCode
      on $projection.SelectedCodeSetPlant = _UsgeDcsnSelectedSetCode.SelectedCodeSetPlant
      and $projection.SelectedCodeSet     = _UsgeDcsnSelectedSetCode.SelectedCodeSet
      and $projection.UsageDecisionCodeGroup = _UsgeDcsnSelectedSetCode.UsageDecisionCodeGroup
                        
{
    @ObjectModel.foreignKey.association: '_SelectedCodeSetPlant'
    key qpac.werks      as SelectedCodeSetPlant,
    //key katalogart as --> hard coded value '3' as where condition,

    @ObjectModel.foreignKey.association: '_SelectedCodeSet'
    key qpac.auswahlmge as SelectedCodeSet,
    key qpac.codegruppe as UsageDecisionCodeGroup,
    //  key qpac.code      --> Not necessary as we want to select only code group

    //  key qpac.versionam --> is always 1 so we could leave out

    //  qpac.bewertung     --> does not make sence

    
    
    /* Associations */
    _SelectedCodeSetPlant,
    _UsageDcsnSelectedCodeSet,
    _SelectedCodeSet,
    _UsgeDcsnSelectedSetCode,
    _UsageDecisionCodeGroup
        
} where qpac.katalogart = '3' and qpac.code is not null and qpac.versionam = '000001'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QPAC",
"QPGR"
],
"ASSOCIATED":
[
"I_INSPUSGEDCSNSELECTEDSET",
"I_PLANT",
"I_USAGEDCSNSELECTEDCODESET",
"I_USAGEDECISIONCODEGROUP",
"I_USGEDCSNSELECTEDSETCODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/