I_TrdgContrFieldCatalogData

@AbapCatalog.sqlViewName: 'ICONTFLDCATALOG'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@EndUserText.label: 'Trading Contract field catalog data'
define view I_TrdgContrFieldCatalogData
  as select from           wbhk    as Header
    inner join             wbhi    as ContractItem   on Header.tkonn = ContractItem.tkonn
    inner join             wbgt    as GenericDocInfo on  ContractItem.tkonn = GenericDocInfo.vbeln
                                                     and ContractItem.tposn = GenericDocInfo.posnr
    inner join             wbhd    as Business       on ContractItem.tkonn = Business.tkonn
    inner join             mara    as Material       on ContractItem.matnr = Material.matnr
    left outer to one join oijnomi as nom_itm        on  ContractItem.tkonn = nom_itm.tcnum
                                                     and ContractItem.tposn = nom_itm.tcitm
    left outer to one join oijnomh as nom_hdr        on nom_hdr.nomtk = nom_itm.nomtk
{
  key ContractItem.tkonn  as ContractNum,
  key ContractItem.tposn  as TradingContractItem,
      case GenericDocInfo.side
      when 'P' then Business.inco1_mm
      when 'S' then Business.inco1_sd
      else ''
      end                 as Incoterms,
      Header.company_code as CompanyCode,
      ContractItem.prctr  as ProfitCenter,
      Header.vkorg        as SalesOrganization,
      Header.vtweg        as DistributionChannel,
      Header.spart        as Division,
      Business.ekorg      as PurchasingOrganization,
      Business.ekgrp      as PurchasingGroup,
      ContractItem.werks  as ContractPlant,
      ContractItem.matnr  as ContractMaterial,
      Header.tctyp        as TradingContractType,
      nom_hdr.vktra       as ModeOfTransport,
      case GenericDocInfo.side
         when 'S' then Header.kunnr   //CustomerName

         when 'P' then Business.elifn //Supplier

         else ''
       end                as Counterparty,
      Material.commodity  as Commodity,
      ContractItem.matkl  as MaterialGroup

}
where
  Business.tposn = '000000';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MARA",
"OIJNOMH",
"OIJNOMI",
"WBGT",
"WBHD",
"WBHI",
"WBHK"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/