I_TranspOrdProcFlwBasicFacts

@EndUserText.label: 'Transportation Order: Proc. Flow Basic Facts'
@ObjectModel:   {representativeKey:  'TransportationOrderUUID',
                 usageType:          {serviceQuality: #C,
                                      sizeCategory:   #XXL,
                                      dataClass:      #TRANSACTIONAL}}
@VDM:           {viewType:           #COMPOSITE}
@AbapCatalog.sqlViewName:           'ITORPFBAS'
@AbapCatalog:   {compiler:           {compareFilter: true},
                 buffering:          {status: #NOT_ALLOWED}}
@AbapCatalog.preserveKey: true
@AccessControl: {authorizationCheck: #CHECK,
                 personalData.blocking:#('TRANSACTIONAL_DATA')}
@Metadata.allowExtensions:  true
@ClientHandling.algorithm:  #SESSION_VARIABLE

define view I_TranspOrdProcFlwBasicFacts
  as select from    I_TransportationOrder      as root

    inner join      I_TransportationOrderStop  as SourceStop      on  root.TransportationOrderUUID             = SourceStop.TransportationOrderUUID
                                                                  and SourceStop.TranspOrdStopSequencePosition = 'F' /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
    inner join      I_TransportationOrderStop  as DestinationStop on  root.TransportationOrderUUID                  = DestinationStop.TransportationOrderUUID
                                                                  and DestinationStop.TranspOrdStopSequencePosition = 'L' /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
    left outer join I_TransportationOrderBlock as block           on  root.TransportationOrderUUID    = block.TransportationOrderUUID
                                                                  and root.TransportationOrderUUID    = block.TranspOrdBlockedNodeUUID
                                                                  and block.TranspOrdBlockIsOverruled = ''
{
  key root.TransportationOrderUUID,
      root.TransportationOrder,
      root.TransportationOrderCategory,
      root._TransportationOrderCategory._Text[1:Language = $session.system_language].TransportationOrderCatDesc,



      // Status Attributes

      root.TranspOrdLifeCycleStatus,
      root._TranspOrdLifeCycleStatus._Text[1:Language = $session.system_language].TranspOrdLifeCycleStatusDesc,
      root.TranspOrdPlanningStatus,
      root._TranspOrdPlanningStatus._Text[1:Language = $session.system_language].TranspOrdPlanningStatusDesc,
      root.TransportationOrderExecSts,
      root._TransportationOrderExecSts._Text[1:Language = $session.system_language].TransportationOrderExecStsDesc,

      // Dates from source stop - new global field names to be established?

      SourceStop.TranspOrdStopReqStartDteTme                                    as SourceStopReqdStartDteTme,
      SourceStop.TranspOrdStopReqEndDteTme                                      as SourceStopReqdEndDteTme,
      SourceStop.TranspOrdStopPlanTranspDteTme                                  as SourceStopPlndTranspDteTme,

      // Dates from the Target Stop - New Global Field Names to be established?

      DestinationStop.TranspOrdStopReqStartDteTme                               as DestStopReqdStartDteTme,
      DestinationStop.TranspOrdStopReqEndDteTme                                 as DestStopReqdEndDteTme,
      DestinationStop.TranspOrdStopPlanTranspDteTme                             as DestStopPlndTranspDteTme,

      // Blocking Attributes

      @ObjectModel.foreignKey.association: '_TranspOrdPlanningBlock'
      root.TranspOrdPlanningBlock,
      @ObjectModel.foreignKey.association: '_TranspOrdExecutionIsBlocked'
      root.TranspOrdExecutionIsBlocked,

      root._TranspOrdPlanningBlock._Text[1:Language = $session.system_language].TranspOrdPlanningBlockDesc,
      root._TranspOrdExecutionIsBlocked._Text[1:Language = $session.system_language].TranspOrdExecutionBlockDesc,

      block.BlockCategory,
      block._BlockCategory._Text[1:Language = $session.system_language].BlockCategoryDesc,
      block.TranspOrdBlockedNodeUUID,

      case root.TranspOrdPlanningBlock
        when 'X' then 'X'
        when '' then
          case root.TranspOrdExecutionIsBlocked
            when 'X' then 'X'
            when '' then
              case root.InvoicingIsBlocked
                when 'X' then 'X'
              else
                ''
              end
          else
            ''
        end
      else
        ''
      end                                                                       as TransportationOrderIsBlocked,
      
      // Additional Attributes

      root.TransportationOrderType,
      root._PurchasingOrganization.OrganizationalUnitExternalID as PurchasingOrgExternalID,
      root._PurchasingGroup.OrganizationalUnitExternalID        as PurchasingGroupExternalID,
      root.TranspOrdResponsiblePerson,
      root.TransportationMode,      

      // Association

      root._TransportationOrderCategory,
      root._TranspOrdLifeCycleStatus,
      root._TranspOrdPlanningStatus,
      root._TransportationOrderExecSts,
      root._TranspOrdPlanningBlock,
      root._TranspOrdExecutionIsBlocked,
      root._TransportationOrderType,
      root._TransportationMode,
      block._BlockCategory
      //_TransportationOrder


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BLOCKCATEGORY",
"I_BLOCKCATEGORYTEXT",
"I_TRANSPORDEXECUTIONBLOCKTEXT",
"I_TRANSPORDEXECUTIONISBLOCKED",
"I_TRANSPORDLIFECYCLESTATUS",
"I_TRANSPORDLIFECYCLESTATUSTEXT",
"I_TRANSPORDPLANNINGBLOCK",
"I_TRANSPORDPLANNINGBLOCKTEXT",
"I_TRANSPORDPLANNINGSTATUS",
"I_TRANSPORDPLANNINGSTATUST",
"I_TRANSPORGANIZATIONALUNIT",
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERBLOCK",
"I_TRANSPORTATIONORDERCATEGORY",
"I_TRANSPORTATIONORDERCATEGORYT",
"I_TRANSPORTATIONORDEREXECSTS",
"I_TRANSPORTATIONORDEREXECSTST",
"I_TRANSPORTATIONORDERSTOP"
],
"ASSOCIATED":
[
"I_BLOCKCATEGORY",
"I_TRANSPORDEXECUTIONISBLOCKED",
"I_TRANSPORDLIFECYCLESTATUS",
"I_TRANSPORDPLANNINGBLOCK",
"I_TRANSPORDPLANNINGSTATUS",
"I_TRANSPORTATIONMODE",
"I_TRANSPORTATIONORDERCATEGORY",
"I_TRANSPORTATIONORDEREXECSTS",
"I_TRANSPORTATIONORDERTYPE"
],
"BASE":
[
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERBLOCK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/