I_TenderingStepEnrcd

@EndUserText:   {label:              'Tendering Step Enriched'}
@Analytics:     {dataCategory:       #DIMENSION,
                 internalName:       #LOCAL}
@ObjectModel:   {representativeKey:  'TenderingStepUUID',
                 usageType:          {serviceQuality: #A,
                                      sizeCategory:   #XL,
                                      dataClass:      #TRANSACTIONAL}}
@VDM:           {viewType:           #BASIC}
@AbapCatalog:   {compiler:           {compareFilter: true},
                 sqlViewName:        'ITENDSTEPE',
                 preserveKey:        true}
@AccessControl: {authorizationCheck: #CHECK,
                 personalData.blocking: #('TRANSACTIONAL_DATA')}
@ClientHandling.algorithm:           #SESSION_VARIABLE
@Metadata.allowExtensions:           true

define view I_TenderingStepEnrcd
  as select from I_TenderingStep
  /* Business Object related Node Associations */
  association [0..*] to I_TenderingRequestEnrcd    as _TenderingRequestEnrcd       on  $projection.TenderingStepUUID       = _TenderingRequestEnrcd.TenderingStepUUID
                                                                                   and $projection.TransportationOrderUUID = _TenderingRequestEnrcd.TransportationOrderUUID
  association [1..1] to I_TransportationOrderEnrcd as _TransportationOrderEnrcd    on  $projection.TransportationOrderUUID = _TransportationOrderEnrcd.TransportationOrderUUID
  association [1..1] to I_TenderingEnrcd           as _TenderingEnrcd              on  $projection.TenderingUUID           = _TenderingEnrcd.TenderingUUID
                                                                                   and $projection.TransportationOrderUUID = _TenderingEnrcd.TransportationOrderUUID
  /* Foreign Key and Text Associations */
  association [0..1] to I_UnitOfMeasure            as _MaximumResponseDurationUnit on  $projection.MaximumResponseDurationUnit = _MaximumResponseDurationUnit.UnitOfMeasure
{
      @ObjectModel.foreignKey.association: '_TransportationOrderEnrcd'
  key TransportationOrderUUID,
      @ObjectModel.text.element:  [ 'TenderingStepSequenceNumber' ]
  key TenderingStepUUID,
      @ObjectModel.foreignKey.association: '_TenderingEnrcd'
      TenderingUUID,
      @Semantics.text: true
      TenderingStepSequenceNumber,
      @ObjectModel.foreignKey.association: '_TenderingType'
      TenderingType,
      @ObjectModel.foreignKey.association: '_TndrgStepLifeCycleStatus'
      TndrgStepLifeCycleStatus,
      @ObjectModel.foreignKey.association: '_TenderingProcessMode'
      TenderingProcessMode,
      @ObjectModel.foreignKey.association: '_CarrierAssignmentMethod'
      CarrierAssignmentMethod,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TenderingPreferredCurrency'
      TenderingPreferredCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TenderingPreferredCurrency'
      TndrgStepAbsltPriceLimitAmount                                                                                                               as TndrgStepAbsolutePriceLimit,
      @DefaultAggregation: #NONE
      RelativePriceLimitInPercent,
      @Semantics.quantity.unitOfMeasure: 'MaximumResponseDurationUnit'
      @DefaultAggregation: #SUM
      cast( cast(
      // h

                 div( cast( MaximumResponseDuration as abap.quan(31, 14)), 10000) * 60
      // min

              + div( mod( cast( cast( cast(MaximumResponseDuration as abap.char(13)) as abap.numc(13)) as abap.int8), 10000), 100)
      // sec

              + division( mod( cast( cast( cast(MaximumResponseDuration as abap.char(13)) as abap.numc(13)) as abap.int8), 100), 60, 5)
              as abap.quan(31,14))                                                            as /scmtms/vdm_net_duration preserving type)         as MaximumResponseDuration,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_MaximumResponseDurationUnit'
      cast(cast('MIN' as abap.unit(3)) as /scmtms/vdm_max_rsp_durn_unit preserving type)                                                           as MaximumResponseDurationUnit,
      @ObjectModel.foreignKey.association: '_TrAlcAndBusShrIsUpdtdByRFQ'
      TrAlcAndBusShrIsUpdtdByRFQ,
      TenderingStepStartDateTime,
      cast(cast(substring(cast(TenderingStepStartDateTime as abap.char(17)), 1, 8) as abap.dats) as /scmtms/vdm_tend_stp_strt_dte preserving type) as TenderingStepStartDate,
      TenderingStepEndDateTime,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT ]
      _TransportationOrderEnrcd,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]
      _TenderingEnrcd,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _TenderingRequestEnrcd,
      _TenderingType,
      _TenderingProcessMode,
      _TndrgStepLifeCycleStatus,
      _CarrierAssignmentMethod,
      _TrAlcAndBusShrIsUpdtdByRFQ,
      _TenderingPreferredCurrency,
      _MaximumResponseDurationUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TENDERINGSTEP"
],
"ASSOCIATED":
[
"I_CARRIERASSIGNMENTMETHOD",
"I_CURRENCY",
"I_TENDERINGENRCD",
"I_TENDERINGPROCESSMODE",
"I_TENDERINGREQUESTENRCD",
"I_TENDERINGTYPE",
"I_TNDRGSTEPLIFECYCLESTATUS",
"I_TRALCANDBUSSHRISUPDTDBYRFQ",
"I_TRANSPORTATIONORDERENRCD",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_TENDERINGSTEP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/