I_TechnicalObjectType

@EndUserText.label: 'Techncial Object Type'
@Analytics: { dataCategory: #DIMENSION,
  dataExtraction : { enabled: true ,
  delta.changeDataCapture.automatic: true }
}
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'ITECHOBJTYPE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#CHECK
@ObjectModel.representativeKey: 'TechnicalObjectType'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
@ObjectModel.alternativeKey:[{id:'OID',element:['EAMTechnicalObjectTypeOID']}]
@ObjectModel.sapObjectNodeType.name:'EAMTechnicalObjectType' 
@ObjectModel.objectIdentifier.oidElement:'EAMTechnicalObjectTypeOID'

define view I_TechnicalObjectType
  as select from           t370k // T370K = Type of technical object

    left outer to one join I_MdiOidConfiguration on I_MdiOidConfiguration.ObjectTypeCode = '5810'
  association [0..*] to I_TechnicalObjectTypeText as _Text on _Text.TechnicalObjectType = $projection.TechnicalObjectType
{
      @ObjectModel.text.association: '_Text'
  key t370k.eqart as TechnicalObjectType,

      //MDI/ODM

      @ObjectModel.filter.enabled:false
      @ObjectModel.sort.enabled:false

      //Context ID is not specified

      case when I_MdiOidConfiguration.Context is initial

      //Composition is disabled

             or I_MdiOidConfiguration.ComposeOid is initial then

           cast( t370k.eqart as technicalobjecttype_oid ) //use your own data element


      //Context ID is specified

           when I_MdiOidConfiguration.Context    is not initial
      //           and dd07l.domvalue_l                 is not initial

            and I_MdiOidConfiguration.ComposeOid is not initial then

           cast( concat( concat( I_MdiOidConfiguration.Context, ':' ), t370k.eqart ) as technicalobjecttype_oid ) //use your own data element

           end    as EAMTechnicalObjectTypeOID, //use your own OID field name


      // Propagate association

      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MDIOIDCONFIGURATION",
"T370K"
],
"ASSOCIATED":
[
"I_TECHNICALOBJECTTYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/