I_TaxBoxStructure2

@AbapCatalog.sqlViewName: 'ITAXBOXSTRUC2'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_ALLOWED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Tax Box Structure definition'
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #CUSTOMIZING

define view I_TaxBoxStructure2
  as select from    fot_atr_tbs      as TaxBoxStructure
    left outer join fot_atr_tbtg_map as TaxGroupBoxAssignment on  TaxBoxStructure.land1      = TaxGroupBoxAssignment.land1
                                                              and TaxBoxStructure.type       = TaxGroupBoxAssignment.type
                                                              and TaxBoxStructure.valid_from = TaxGroupBoxAssignment.valid_from
    left outer join fot_atr_tax_box  as TaxBox                on  TaxGroupBoxAssignment.land1      = TaxBox.land1
                                                              and TaxGroupBoxAssignment.valid_from = TaxBox.valid_from
                                                              and TaxGroupBoxAssignment.type       = TaxBox.type
                                                              and TaxGroupBoxAssignment.tax_box    = TaxBox.tax_box
    left outer join fot_atr_tax_grp  as TaxGroup              on  TaxGroupBoxAssignment.land1      = TaxGroup.land1
                                                              and TaxGroupBoxAssignment.valid_from = TaxGroup.valid_from
                                                              and TaxGroupBoxAssignment.type       = TaxGroup.type
                                                              and TaxGroupBoxAssignment.tax_group  = TaxGroup.tax_group
    left outer join t007b as TransactionKey             on TaxGroup.ktosl = TransactionKey.ktosl
  association [0..*] to fot_atr_tbs_typt as _TaxBoxStructureTypeText on  $projection.Country             = _TaxBoxStructureTypeText.land1
                                                                     and $projection.TaxBoxStructureType = _TaxBoxStructureTypeText.type
  association [0..*] to fot_atr_tax_boxt as _TaxBoxText              on  $projection.Country             = _TaxBoxText.land1
                                                                     and $projection.ValidFrom           = _TaxBoxText.valid_from
                                                                     and $projection.TaxBoxStructureType = _TaxBoxText.type
                                                                     and $projection.TaxBox              = _TaxBoxText.tax_box
{
      //  key TaxBoxStructure.mandt                                                               as SAPClient,

  key TaxBoxStructure.land1                                                               as Country,
  key TaxBoxStructure.type                                                                as TaxBoxStructureType,
  key TaxBoxStructure.valid_from                                                          as ValidFrom,
  key TaxGroupBoxAssignment.tax_group                                                     as TaxGroup,
  key TaxGroup.mwskz                                                                      as TaxCode,
  key TaxGroup.ktosl                                                                      as TransactionTypeDetermination,
  key TaxGroupBoxAssignment.tax_box                                                       as TaxBox,
      TaxBoxStructure.valid_to                                                            as ValidTo,
      _TaxBoxStructureTypeText[1: langu = $session.system_language].text                  as TaxBoxStructureTypeName,
      TaxBoxStructure.tax_box_struct                                                      as TaxBoxStructure,
      tax_rept_country  as                                                                TaxCountry,
      
      _TaxBoxText[1: langu = $session.system_language].text                               as TaxBoxName,

      TaxBox.tax_box_op_type                                                              as TaxBoxOutputType,
      TaxBox.tax_box_cond                                                                 as TaxBoxCondition,


      TaxGroup.txdat_from                                                                 as TaxRateValidityStartDate,
      TaxGroup.txdat_to                                                                   as TaxRateValidityEndDate,
      TransactionKey.stazf                                                                as TaxIsNotDeductible,
      TaxGroup.shkzg_umsv                                                                 as DebitCreditCode,
      TaxGroup.txjcd                                                                      as TaxJurisdiction,
      TaxGroup.blart                                                                      as AccountingDocumentType,
      TaxGroup.umskz                                                                      as SpecialGLCode,
      TaxGroup.ktokk                                                                      as SupplierAccountGroup,
      TaxGroup.opera                                                                      as TaxGroupOperation,
      TaxGroup.fc_code                                                                    as TaxGroupFreeClassification,
      TaxGroup.racct                                                                      as GLAccount,
      TaxGroupBoxAssignment.opera                                                         as TaxBoxAggregationOperation
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FOT_ATR_TAX_BOX",
"FOT_ATR_TAX_BOXT",
"FOT_ATR_TAX_GRP",
"FOT_ATR_TBS",
"FOT_ATR_TBS_TYPT",
"FOT_ATR_TBTG_MAP",
"T007B"
],
"ASSOCIATED":
[
"FOT_ATR_TAX_BOXT",
"FOT_ATR_TBS_TYPT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/