I_TaxAuthorityValueHelp

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking :#BLOCKED_DATA_EXCLUDED
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel: { dataCategory: #VALUE_HELP,
                representativeKey: 'BusinessPartner',
                usageType: { serviceQuality: #X,
                             dataClass: #MASTER,
                             sizeCategory: #XL },
               supportedCapabilities: [#ANALYTICAL_DIMENSION,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #SEARCHABLE_ENTITY,
                                        #SQL_DATA_SOURCE,
                                        #VALUE_HELP_PROVIDER]
             }
@Search.searchable: true
@VDM:{ lifecycle.contract.type: #SAP_INTERNAL_API ,
       viewType: #COMPOSITE }
@EndUserText.label: 'Tax Authority'
@Consumption.ranked: true
define view entity I_TaxAuthorityValueHelp
  as select from I_BusinessPartner            as BusinessPartner
    inner join   I_BusinessPartner_to_BP_Role as BusinessPartnerRole   on BusinessPartnerRole.BusinessPartner = BusinessPartner.BusinessPartner
    inner join   I_SupplierToBusinessPartner  as SupptoBusinesspartner on BusinessPartner.BusinessPartnerUUID = SupptoBusinesspartner.BusinessPartnerUUID
    inner join   I_SupplierCompany            as SupplierToCompanyCode on SupptoBusinesspartner.Supplier = SupplierToCompanyCode.Supplier

  association to I_SupplierCompany as _SupplierCompany on  $projection.Supplier    = _SupplierCompany.Supplier
                                                       and $projection.CompanyCode = _SupplierCompany.CompanyCode
{

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      @ObjectModel.text.element:  ['BusinessPartnerName']
  key BusinessPartnerRole.BusinessPartner,
      //@Search: { defaultSearchElement: true, ranking: #LOW } //Company Code would be filtered via binding

  key SupplierToCompanyCode.CompanyCode,
      @UI.hidden: true
      BusinessPartner.BusinessPartnerUUID,
      @Search: { defaultSearchElement: true, ranking: #LOW }
      SupptoBusinesspartner.Supplier,
      @Semantics.text: true
      @EndUserText.label: 'Business Partner Name'
      @EndUserText.quickInfo:'Business Partner Name'
      //Search not possible on string function

      BusinessPartner.BusinessPartnerName,


      @Consumption.hidden: true
      SupptoBusinesspartner._Supplier,
      @Consumption.hidden: true
      BusinessPartnerRole.ValidFrom,
      @Consumption.hidden: true
      BusinessPartnerRole.ValidTo,
      @Consumption.hidden: true
      BusinessPartnerRole._BusinessPartner,
      @Consumption.hidden: true
      BusinessPartnerRole.BusinessPartnerRole,

      @Consumption.hidden: true
      BusinessPartner.AuthorizationGroup,
      @Semantics.booleanIndicator
      @Consumption.hidden: true
      BusinessPartner.IsBusinessPurposeCompleted,
      @Consumption.hidden: true
      BusinessPartner.DataControllerSet,
      @Consumption.hidden: true
      BusinessPartner.DataController1,
      @Consumption.hidden: true
      BusinessPartner.DataController2,
      @Consumption.hidden: true
      BusinessPartner.DataController3,
      @Consumption.hidden: true
      BusinessPartner.DataController4,
      @Consumption.hidden: true
      BusinessPartner.DataController5,
      @Consumption.hidden: true
      BusinessPartner.DataController6,
      @Consumption.hidden: true
      BusinessPartner.DataController7,
      @Consumption.hidden: true
      BusinessPartner.DataController8,
      @Consumption.hidden: true
      BusinessPartner.DataController9,
      @Consumption.hidden: true
      BusinessPartner.DataController10,

      @Consumption.hidden: true
      _SupplierCompany

}
where
      BusinessPartnerRole.BusinessPartnerRole = 'TAX000'
  and BusinessPartnerRole.ValidTo             > tstmp_current_utctimestamp( )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNER_TO_BP_ROLE",
"I_SUPPLIERCOMPANY",
"I_SUPPLIERTOBUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_SUPPLIER",
"I_SUPPLIERCOMPANY"
],
"BASE":
[
"I_BUSINESSPARTNER_TO_BP_ROLE",
"I_SUPPLIERTOBUSINESSPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/