I_SupplierInvoiceOriginValHelp

@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'SupplierInvoiceOrigin'
@VDM.viewType : #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.sqlViewName: 'ISUPINVCORGVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 
@EndUserText.label: 'Supplier Invoice List Origin Value Help'
define view I_SupplierInvoiceOriginValHelp 
    as select from dd07t 

    association [0..1] to I_Language as _Language on $projection.Language = $session.system_language

{

  key cast ( substring( domvalue_l, 1, 1 ) as mmiv_invoice_origin preserving type)      as SupplierInvoiceOrigin,
      @Semantics.language: true
  key ddlanguage                                                                        as Language,
      @Semantics.text: true
      cast ( ddtext as mmiv_description_text preserving type)                           as SupplierInvoiceOriginDesc,

      //association

      _Language
      
}
where
      domname  = 'MMIV_INVOICE_ORIGIN'
  and as4local = 'A'
  and(
       domvalue_l = ' ' //Online

    or domvalue_l = '1' //ERS

    or domvalue_l = '2' //ERS Null

    or domvalue_l = '3' //Batch

    or domvalue_l = '4' //EDI

    or domvalue_l = '5' //Cancellation

    or domvalue_l = '6' //Invoicing Plan

    or domvalue_l = '7' //Transfer Prices

    or domvalue_l = '8' //Revaluation

    or domvalue_l = 'A' //Invoice from Parking Function 

    or domvalue_l = 'B' //BAPI

    or domvalue_l = 'D' //SRM Invoice

    or domvalue_l = 'G' //External Service (A2A)

    or domvalue_l = 'H' //SOA B2B

    or domvalue_l = 'I' //cXML

    or domvalue_l = 'J' //cXML from Parking Function

    or domvalue_l = 'K' //Consignment

    or domvalue_l = 'L' //Recurring Supplier Invoice  

    or domvalue_l = 'M' //Intercompany Supplier Invoice

    or domvalue_l = 'N' //RAP API

    //Not:    

    // 9 WEB Invoice

    // C Account Maintenance

    // E BAPI Account Maintenance 

)
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/