I_SuplrInvcItemPurOrdRefAPI01

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ISIPORDREFAPI01'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType : #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Purchase Order Ref of Supplier Invoice'
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Metadata.ignorePropagatedAnnotations:true
@AbapCatalog.preserveKey:true

define view I_SuplrInvcItemPurOrdRefAPI01
  as select from I_SupplierInvoiceItemPurOrdRef as item
    inner join   I_SupplierInvoiceAPI01 on  item.SupplierInvoice = I_SupplierInvoiceAPI01.SupplierInvoice
                                        and item.FiscalYear      = I_SupplierInvoiceAPI01.FiscalYear
  association [1..1] to I_SupplierInvoiceAPI01        as _SupplierInvoiceAPI01        on  $projection.SupplierInvoice = _SupplierInvoiceAPI01.SupplierInvoice
                                                                                      and $projection.FiscalYear      = _SupplierInvoiceAPI01.FiscalYear
  association [1..*] to I_SuplrInvcItmAcctAssgmtAPI01 as _SuplrInvcItmAcctAssgmtAPI01 on  $projection.SupplierInvoice     = _SuplrInvcItmAcctAssgmtAPI01.SupplierInvoice
                                                                                      and $projection.FiscalYear          = _SuplrInvcItmAcctAssgmtAPI01.FiscalYear
                                                                                      and $projection.SupplierInvoiceItem = _SuplrInvcItmAcctAssgmtAPI01.SupplierInvoiceItem
{
      //Key

  key item.SupplierInvoice,
  key item.FiscalYear,
  key item.SupplierInvoiceItem,

      item.PurchaseOrder,
      item.PurchaseOrderItem,
      item.Plant,
      item.SupplierInvoiceItemText,
      item.PurchaseOrderItemMaterial,
      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      @Semantics.unitOfMeasure: true
      item.PurchaseOrderQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      item.QuantityInPurchaseOrderUnit,
      @ObjectModel.foreignKey.association: '_PurOrdPriceUnitOfMeasure'
      @Semantics.unitOfMeasure: true
      item.PurchaseOrderPriceUnit,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
      item.QtyInPurchaseOrderPriceUnit,
      item.SuplrInvcDeliveryCostCndnType,
      item.SuplrInvcDeliveryCostCndnStep,
      item.SuplrInvcDeliveryCostCndnCount,
      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      item.DocumentCurrency,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      item.SupplierInvoiceItemAmount,
      item.IsSubsequentDebitCredit,
      item.TaxCode,
      item.TaxJurisdiction,
      item.ReferenceDocument,
      item.ReferenceDocumentFiscalYear,
      item.ReferenceDocumentItem,
      item.DebitCreditCode,
      item.FreightSupplier,
      item.IsNotCashDiscountLiable,
      item.SuplrInvcItemHasPriceVariance,
      item.SuplrInvcItemHasQtyVariance,
      item.SuplrInvcItemHasDateVariance,
      item.SuplrInvcItemHasOrdPrcQtyVarc,
      item.SuplrInvcItemHasOtherVariance,
      item.SuplrInvcItemHasAmountOutsdTol,
      item.SuplrInvcItmHasQualityVariance,
      item.TaxCountry,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      item.SuplrInvcItmUnplndDelivCost,

      _SupplierInvoiceAPI01,
      _SuplrInvcItmAcctAssgmtAPI01,
      item._Currency,
      _UnitOfMeasure,
      _PurOrdPriceUnitOfMeasure
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPPLIERINVOICEAPI01",
"I_SUPPLIERINVOICEITEMPURORDREF"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_SUPLRINVCITMACCTASSGMTAPI01",
"I_SUPPLIERINVOICEAPI01",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_SUPPLIERINVOICEITEMPURORDREF"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/