I_SupDmndAllDocSupProtC

@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics: {
  dataCategory:#CUBE,
  internalName:#LOCAL
}
@VDM: {
  viewType: #COMPOSITE
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADSPTC',
  compiler.compareFilter: true,
  preserveKey:true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XXL
   }
}
@Metadata:{
  allowExtensions:              true,
  ignorePropagatedAnnotations:  true
}
@EndUserText.label: 'Supply Protection relevant for Supply Assignment'
define view I_SupDmndAllDocSupProtC
  as select from           I_ARunSupplyProtection as Demand
    inner join             I_SupDmndOvwPlant      as Plant            on Demand.Plant = Plant.Plant
    left outer to one join P_ARunAssgmtDmnd       as Assgmt           on  Demand.StartDate               = Assgmt.RequestedDate
                                                                      and Demand.SupProtTimeBucketUUID   = Assgmt.SupProtTimeBucketUUID
                                                                      and Demand.ProductAvailabilityDate = Assgmt.ProductAvailabilityDate
                                                                      and Demand.RequirementType         = Assgmt.RequirementType
                                                                      and Demand.Material                = Assgmt.Material
                                                                      and Demand.Plant                   = Assgmt.Plant
    left outer to one join I_ARunCalendarDate     as CalDate          on Demand.StartDate = CalDate.CalendarDate
    left outer to one join I_CalendarMonthName    as CalMonth         on CalDate.CalendarMonth = CalMonth.CalendarMonth
    left outer to one join I_ARunTimeUnitText     as ARunTimeUnitText on  ARunTimeUnitText.ARunDisplayTimeUnit = '02'
                                                                      and ARunTimeUnitText.Language            = $session.system_language
  association [0..1] to I_UnitOfMeasure as _BaseUnit on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
{
      @EndUserText.label: 'Supply Protection Time Bucket UUID'
  key Demand.SupProtTimeBucketUUID,
      @EndUserText.label: 'Requirement Type'
      Demand.RequirementType,
      Demand.StartDate                                                     as RequestedDate,
      Demand.ProductAvailabilityDate                                       as ProductAvailabilityDate,
      Demand.RequestedDeliveryDate                                         as RequestedDeliveryDate,
      @EndUserText.label: 'Time Bucket Start Date'
      Demand.StartDate,
      @EndUserText.label: 'Time Bucket End Date'
      Demand.EndDate,
      @EndUserText.label: 'Protected Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      SupProtProtectedQuantity,
      @EndUserText.label: 'Consumed Protected Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      SupProtConsumedQuantity,
      @EndUserText.label: 'Quantity Open for Consumption'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ARunSupProtUnconsumedQty,
      @EndUserText.label: 'Temporary Assigned Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      Assgmt.ARunTmpAssignedQuantityInBsUnt,
      @EndUserText.label: 'Open Demand Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ( Demand.ARunSupProtUnconsumedQty
          - coalesce( Assgmt.AssignedQuantityInBaseUnit , 0 )
      )                                                                    as OpenDemandQuantity,
      @EndUserText.label: 'Base Unit of Measure'
      @ObjectModel.foreignKey.association: '_BaseUnit'
      Demand.BaseUnit,
      Demand.RequirementSegment,
      @EndUserText.label: 'Year'
      @Semantics.calendar.year: true
      CalDate.CalendarYear,
      @EndUserText.label: 'Month'
      @Semantics.calendar.month: true
      @ObjectModel.text.element: 'CalendarMonthName'
      CalDate.CalendarMonth,
      @Semantics.text: true
      @EndUserText.label: 'Month'
      CalMonth.CalendarMonthName,
      @EndUserText.label: 'Week'
      @Semantics.calendar.week: true
      concat_with_space( ARunDisplayTimeUnitText, CalDate.CalendarWeek, 1) as CalendarWeek,
      @EndUserText.label: 'Day'
      @Semantics.calendar.dayOfMonth: true
      CalDate.CalendarDay,
      @EndUserText.label: 'Product'
      Demand.Material,
      @EndUserText.label: 'Product Group'
      Demand.MaterialGroup,
      @EndUserText.label: 'Product Type'
      Demand.MaterialType,
      @EndUserText.label: 'Generic Article'
      Demand.CrossPlantConfigurableProduct,
      Demand.Plant,
      Plant.SalesOrganization,
      Plant.DistributionChannel,
      Plant.Division,
      Plant.SalesDistrict,
      Plant.PlantCustomer                                                  as Customer,
      Plant.CompanyCode                                                    as CompanyCode,
      cast( '' as lgort_d )                                                as StorageLocation,
      @Semantics.unitOfMeasure: true
      cast( ' ' as meins )                                                 as SupAssgmtAggrgQtyUnit,
      @EndUserText.label: 'Supply Protection Name'
      SupplyProtectionName,
      @EndUserText.label: 'Characteristic 1'
      SupProtCharc01CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 1'
      SupProtCharc01ValueID,
      @EndUserText.label: 'Characteristic 2'
      SupProtCharc02CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 2'
      SupProtCharc02ValueID,
      @EndUserText.label: 'Characteristic 3'
      SupProtCharc03CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 3'
      SupProtCharc03ValueID,
      @EndUserText.label: 'Characteristic 4'
      SupProtCharc04CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 4'
      SupProtCharc04ValueID,
      @EndUserText.label: 'Characteristic 5'
      SupProtCharc05CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 5'
      SupProtCharc05ValueID,
      @EndUserText.label: 'Characteristic 6'
      SupProtCharc06CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 6'
      SupProtCharc06ValueID,
      @EndUserText.label: 'Characteristic 7'
      SupProtCharc07CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 7'
      SupProtCharc07ValueID,
      @EndUserText.label: 'Characteristic 8'
      SupProtCharc08CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 8'
      SupProtCharc08ValueID,
      @EndUserText.label: 'Characteristic 9'
      SupProtCharc09CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 9'
      SupProtCharc09ValueID,
      @EndUserText.label: 'Characteristic 10'
      SupProtCharc10CtlgPathUUID,
      @EndUserText.label: 'Characteristic Value 10'
      SupProtCharc10ValueID,
      _BaseUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARUNCALENDARDATE",
"I_ARUNSUPPLYPROTECTION",
"I_ARUNTIMEUNITTEXT",
"I_CALENDARMONTHNAME",
"I_SUPDMNDOVWPLANT",
"P_ARUNASSGMTDMND"
],
"ASSOCIATED":
[
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/