I_SupDmndAllDocSupProt

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #COMPOSITE
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #NOT_REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADSPT',
  compiler.compareFilter: true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #X,
     sizeCategory:   #XXL
   }
}
@EndUserText.label: 'Supply Protection relevant for Supply Assignment'
define view I_SupDmndAllDocSupProt
  as select from I_ARunSupplyProtection as SUP
{
  cast( '' as vbeln_va )      as RequirementDocumentNumber,
  cast( '000000' as posnr )   as RequirementDocumentItem,
  SUP.SupProtTimeBucketUUID,
  SUP.StartDate               as RequestedDate,
  SUP.ProductAvailabilityDate as ProductAvailabilityDate,
  SUP.RequestedDeliveryDate   as RequestedDeliveryDate,
  SUP.EndDate,
  SUP.RequirementType,
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'
  SupProtProtectedQuantity    as RequestedRqmtQtyInBaseUnit,
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'
  SupProtProtectedQuantity    as ConfirmedRqmtQtyInBaseUnit,
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'
  SupProtConsumedQuantity     as DeliveredQuantityInBaseUnit,
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'
  ARunSupProtUnconsumedQty    as OpenDemandQuantity,
  @Semantics.unitOfMeasure: true
  BaseUnit,
  0                           as AssignedQuantityInBaseUnit,
  0                           as NormalAssignedQuantityInBsUnt,
  0                           as PreviewAssignedQuantityInBsUnt,
  SUP.Material,
  SUP.Plant,
  SUP.SupplyProtectionName,
  SUP.SupProtLifecycleStatus,
  SUP.SupProtGroupPriorityValue,
  SUP.MaterialGroup,
  SUP.CrossPlantConfigurableProduct,
  SUP.SegmentationStrategy,
  SUP.SegmentationStrategyScope,
  SUP.RequirementSegment,
  SUP.Division,
  SUP.IsInternalBatchManaged
}
where
  ARunSupProtUnconsumedQty > 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARUNSUPPLYPROTECTION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/