I_SupDmndAllDocRetSlsOrdC

@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics: {
  dataCategory: #CUBE,
  internalName:#LOCAL
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADRETSOC',
  compiler.compareFilter: true,
  preserveKey:true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XXL
   }
}
@Metadata:{
  allowExtensions:              true,
  ignorePropagatedAnnotations:  true
}
@EndUserText.label: 'Cube View for Return Sales Orders Details'
define view I_SupDmndAllDocRetSlsOrdC
  as select from    I_SupDmndAllDocRetSlsOrd as Supply
    inner join      I_SupDmndOvwPlant        as Plant            on Supply.Plant = Plant.Plant
    left outer join P_ARunAssgmtSup          as Assgmt           on  Supply.SupplyNumber       = Assgmt.SupplyNumber
                                                                 and Supply.SupplyItem         = Assgmt.SupplyItem
                                                                 and Supply.SupplyScheduleLine = Assgmt.SupplyScheduleLine
                                                                 and Supply.Plant              = Assgmt.Plant
                                                                 and Supply.Material           = Assgmt.Material
                                                                 and Supply.StorageLocation    = Assgmt.StorageLocation
                                                                 and Supply.Batch              = Assgmt.Batch
                                                                 and Supply.AssignedSupplyType = Assgmt.AssignedSupplyType
    left outer join I_ARunCalendarDate       as CalDate          on Supply.ProductAvailabilityDate = CalDate.CalendarDate
    left outer join I_CalendarMonthName      as CalMonth         on CalDate.CalendarMonth = CalMonth.CalendarMonth
    left outer join I_ARunTimeUnitText       as ARunTimeUnitText on  ARunTimeUnitText.ARunDisplayTimeUnit = '02'
                                                                 and ARunTimeUnitText.Language            = $session.system_language
  association [0..1] to I_ProductText                 as _ProductText              on  $projection.Material  = _ProductText.Product
                                                                                   and _ProductText.Language = $session.system_language
  association [0..1] to I_ProductGroupText            as _ProductGroupText         on  $projection.MaterialGroup  = _ProductGroupText.MaterialGroup
                                                                                   and _ProductGroupText.Language = $session.system_language
  //Should it be replaced with I_MaterialGroupText as ProductGroup has status Deprecated?

  association [0..1] to I_ProductTypeText             as _ProductTypeText          on  $projection.MaterialType  = _ProductTypeText.ProductType
                                                                                   and _ProductTypeText.Language = $session.system_language
  association [0..1] to I_SalesOrganizationText       as _SalesOrgText             on  $projection.SalesOrganization = _SalesOrgText.SalesOrganization
                                                                                   and _SalesOrgText.Language        = $session.system_language
  association [0..1] to I_DistributionChannelText     as _DistrChnl                on  $projection.DistributionChannel = _DistrChnl.DistributionChannel
                                                                                   and _DistrChnl.Language             = $session.system_language
  association [0..1] to I_DivisionText                as _Divn                     on  $projection.Division = _Divn.Division
                                                                                   and _Divn.Language       = $session.system_language
  association [0..1] to I_SalesDistrictText           as _SalesDist                on  $projection.SalesDistrict = _SalesDist.SalesDistrict
                                                                                   and _SalesDist.Language       = $session.system_language
  association [0..1] to I_Plant                       as _Plant                    on  $projection.Plant = _Plant.Plant
  association [0..1] to I_CompanyCode                 as _CompanyCode              on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Customer                    as _Customer                 on  $projection.Customer = _Customer.Customer

  association [0..1] to I_UnitOfMeasure               as _BaseUnit                 on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure

  association [0..1] to I_PurchasingOrganization      as _PurchasingOrganization   on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
                                                                                   and $projection.CompanyCode            = _PurchasingOrganization.CompanyCode
  association [0..1] to I_PurchasingGroup             as _PurchasingGroup          on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_SupDmndAllDocSupTypeT       as _SupText                  on  $projection.AssignedSupplyType = _SupText.AssignedSupplyType
                                                                                   and _SupText.Language              = $session.system_language
  association [0..1] to I_SupDmndAllDocSupSourceT     as _SupSrceText              on  $projection.SupAssgmtSource = _SupSrceText.SupAssgmtSource
                                                                                   and _SupSrceText.Language       = $session.system_language
  association [0..1] to I_SalesDocumentRjcnReasonText as _SalesDocumentRjcnReasonT on  $projection.SalesDocumentRjcnReason = _SalesDocumentRjcnReasonT.SalesDocumentRjcnReason
                                                                                   and _SalesDocumentRjcnReasonT.Language  = $session.system_language
  association [0..1] to I_SDDocumentReasonText        as _SDDocumentReasonT        on  $projection.SDDocumentReason = _SDDocumentReasonT.SDDocumentReason
                                                                                   and _SDDocumentReasonT.Language  = $session.system_language
{
       @ObjectModel.text.association: '_ProductText'
  key  Supply.Material,
       @ObjectModel.text.association: '_Plant'
  key  Supply.Plant,
  key  Supply.Batch,
  key  Supply.StorageLocation,
       @EndUserText.label: 'Supply Document No.'
  key  Supply.SupplyNumber,
       @EndUserText.label: 'Supply Document Item'
  key  Supply.SupplyItem,
       @EndUserText.label: 'Supply Schedule Line'
  key  Supply.SupplyScheduleLine,
       @EndUserText.label: 'Supply Delivery Date'
  key  Supply.ProductAvailabilityDate,
       @ObjectModel.text.association: '_SupText'
       @EndUserText.label: 'Supply Type'
  key  Supply.AssignedSupplyType,
       Supply.RequestedDeliveryDate,
       @EndUserText.label: 'Total Supply Quantity'
       @DefaultAggregation: #SUM
       @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
       Supply.TotalQuantity,
       @EndUserText.label: 'Open Supply Quantity'
       @DefaultAggregation: #SUM
       @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
       ( Supply.OpenSupplyQuantity
         - coalesce( Assgmt.AssignedQuantityInBaseUnit , 0 )
       )                                                                                       as OpenSupplyQuantity,
       @EndUserText.label: 'Total Assigned Quantity'
       @DefaultAggregation: #SUM
       @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
       Assgmt.AssignedQuantityInBaseUnit,
       @EndUserText.label: 'Normal Assigned Quantity'
       @DefaultAggregation: #SUM
       @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
       Assgmt.NormalAssignedQuantityInBsUnt,
       @EndUserText.label: 'Preview Assigned Quantity'
       @DefaultAggregation: #SUM
       @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
       Assgmt.PreviewAssignedQuantityInBsUnt,
       @EndUserText.label: 'Temporary Assigned Quantity'
       @DefaultAggregation: #SUM
       @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
       Assgmt.ARunTmpAssignedQuantityInBsUnt,
       @ObjectModel.foreignKey.association: '_BaseUnit'
       Supply.BaseUnit,
       @EndUserText.label: 'Year'
       @Semantics.calendar.year: true
       CalDate.CalendarYear,
       @EndUserText.label: 'Month'
       @Semantics.calendar.month: true
       @ObjectModel.text.element: 'CalendarMonthName'
       CalDate.CalendarMonth,
       @Semantics.text: true
       @EndUserText.label: 'Month'
       CalMonth.CalendarMonthName,
       @EndUserText.label: 'Week'
       @Semantics.calendar.week: true
       concat_with_space( ARunDisplayTimeUnitText, CalDate.CalendarWeek, 1)                    as CalendarWeek,
       @EndUserText.label: 'Day'
       @Semantics.calendar.dayOfMonth: true
       CalDate.CalendarDay,
       @ObjectModel.text.association: '_ProductGroupText'
       Supply.MaterialGroup,
       @ObjectModel.text.association: '_ProductTypeText'
       @EndUserText.label: 'Product Type'
       MaterialType,
       @EndUserText.label: 'Supply Source'
       @ObjectModel.text.association: '_SupSrceText'
       Supply.SupAssgmtSource,
       @EndUserText.label: 'Generic Article'
       Supply.CrossPlantConfigurableProduct,
       Supply.StockSegment,
       @ObjectModel.text.association: '_SalesOrgText'
       coalesce( Supply.SalesOrganization, coalesce( Plant.SalesOrganization, '' ) )           as SalesOrganization,
       @ObjectModel.text.association: '_DistrChnl'
       coalesce( Supply.DistributionChannel, coalesce( Plant.DistributionChannel, '') )        as DistributionChannel,
       @ObjectModel.text.association: '_Divn'
       coalesce( Supply.Division, coalesce( Plant.Division, '') )                              as Division,
       @ObjectModel.text.association: '_SalesDist'
       coalesce( Supply.SalesDistrict, coalesce( Plant.SalesDistrict, '') )                    as SalesDistrict,
       @ObjectModel.text.association: '_Customer'
       coalesce( Supply.Customer, coalesce( Plant.PlantCustomer, '') )                         as Customer,
       @ObjectModel.text.association: '_CompanyCode'
       coalesce( Supply.CompanyCode, coalesce( Plant.CompanyCode, '') )                        as CompanyCode,
       @ObjectModel.text.association: '_PurchasingOrganization'
       coalesce( Supply.PurchasingOrganization, coalesce( Plant.PurchasingOrganization, '' ) ) as PurchasingOrganization,
       @ObjectModel.text.association: '_PurchasingGroup'
       Supply.PurchasingGroup,
       @ObjectModel.text.association: '_SalesDocumentRjcnReasonT'
       Supply.SalesDocumentRjcnReason,
       @ObjectModel.text.element: ['ReturnReasonName']
       Supply.SDDocumentReason,
       _SDDocumentReasonT.SDDocumentReasonText                                                 as ReturnReasonName,
       @Semantics.unitOfMeasure: true
       cast( ' ' as meins )                                                                    as SupAssgmtAggrgQtyUnit,
       @Semantics.amount.currencyCode: 'DocumentCurrency'
       Supply.NetPriceAmount,
       @Semantics.currencyCode: true
       Supply.DocumentCurrency,
       @Semantics.amount.currencyCode: 'DocumentCurrency'
       cast ( Supply.OpenSupplyQuantity * NetPriceAmount as netwr )                            as ActlAmt,
       //Associations

       _ProductText,
       _ProductGroupText,
       _ProductTypeText,
       @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
       _SupSrceText,
       _SalesOrgText,
       _DistrChnl,
       _Divn,
       _SalesDist,
       _Plant,
       _CompanyCode,
       _Customer,
       _BaseUnit,
       _PurchasingOrganization,
       _PurchasingGroup,
       _SalesDocumentRjcnReasonT,
       @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
       _SupText
}
where
  TotalQuantity > 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARUNCALENDARDATE",
"I_ARUNTIMEUNITTEXT",
"I_CALENDARMONTHNAME",
"I_SDDOCUMENTREASONTEXT",
"I_SUPDMNDALLDOCRETSLSORD",
"I_SUPDMNDOVWPLANT",
"P_ARUNASSGMTSUP"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_PLANT",
"I_PRODUCTGROUPTEXT",
"I_PRODUCTTEXT",
"I_PRODUCTTYPETEXT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SALESDISTRICTTEXT",
"I_SALESDOCUMENTRJCNREASONTEXT",
"I_SALESORGANIZATIONTEXT",
"I_SDDOCUMENTREASONTEXT",
"I_SUPDMNDALLDOCSUPSOURCET",
"I_SUPDMNDALLDOCSUPTYPET",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/