I_SupDmndAllDocPurgContrRefC

@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics: {
  dataCategory: #CUBE,
  internalName:#LOCAL
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADPCRC',
  compiler.compareFilter: true,
  preserveKey:true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XXL
   }
}
@Metadata:{
  allowExtensions:              true,
  ignorePropagatedAnnotations:  true
}
@EndUserText.label: 'Cube View for Purchasing Contract Reference Details'
define view I_SupDmndAllDocPurgContrRefC
  as select from    P_SupDmndAllDocPurgContrRel as Rel
    inner join      I_SupDmndAllDocPurgContr    as Supply           on  Rel.PurchaseContract     = Supply.SupplyNumber
                                                                    and Rel.PurchaseContractItem = Supply.SupplyItem
    left outer join I_SupDmndOvwPlant           as Plant            on Supply.Plant = Plant.Plant
    left outer join I_ARunCalendarDate          as CalDate          on Supply.ProductAvailabilityDate = CalDate.CalendarDate
    left outer join I_CalendarMonthName         as CalMonth         on CalDate.CalendarMonth = CalMonth.CalendarMonth
    left outer join I_ARunTimeUnitText          as ARunTimeUnitText on  ARunTimeUnitText.ARunDisplayTimeUnit = '02'
                                                                    and ARunTimeUnitText.Language            = $session.system_language
  association [0..1] to I_ProductText              as _ProductText            on  $projection.Material  = _ProductText.Product
                                                                              and _ProductText.Language = $session.system_language
  association [0..1] to I_ProductGroupText         as _ProductGroupText       on  $projection.MaterialGroup  = _ProductGroupText.MaterialGroup
                                                                              and _ProductGroupText.Language = $session.system_language
  //Should it be replaced with I_MaterialGroupText as ProductGroup has status Deprecated?

  association [0..1] to I_ProductTypeText          as _ProductTypeText        on  $projection.MaterialType  = _ProductTypeText.ProductType
                                                                              and _ProductTypeText.Language = $session.system_language
  association [0..1] to I_SalesOrganizationText    as _SalesOrgText           on  $projection.SalesOrganization = _SalesOrgText.SalesOrganization
                                                                              and _SalesOrgText.Language        = $session.system_language
  association [0..1] to I_DistributionChannelText  as _DistrChnl              on  $projection.DistributionChannel = _DistrChnl.DistributionChannel
                                                                              and _DistrChnl.Language             = $session.system_language
  association [0..1] to I_DivisionText             as _Divn                   on  $projection.Division = _Divn.Division
                                                                              and _Divn.Language       = $session.system_language
  association [0..1] to I_SalesDistrictText        as _SalesDist              on  $projection.SalesDistrict = _SalesDist.SalesDistrict
                                                                              and _SalesDist.Language       = $session.system_language
  association [0..1] to I_Plant                    as _Plant                  on  $projection.Plant = _Plant.Plant
  association [0..1] to I_CompanyCode              as _CompanyCode            on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Customer                 as _Customer               on  $projection.Customer = _Customer.Customer

  association [0..1] to I_UnitOfMeasure            as _BaseUnit               on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure

  association [0..1] to I_PurchasingOrganization   as _PurchasingOrganization on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
                                                                              and $projection.CompanyCode            = _PurchasingOrganization.CompanyCode
  association [0..1] to I_PurchasingGroup          as _PurchasingGroup        on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_SupDmndAllDocSupTypeT    as _SupText                on  $projection.AssignedSupplyType = _SupText.AssignedSupplyType
                                                                              and _SupText.Language              = $session.system_language
  association [0..1] to I_PurgDocumentCategoryText as _CatText                on  $projection.PurchasingDocumentCategory = _CatText.PurchasingDocumentCategory
                                                                              and _CatText.Language                      = $session.system_language
  association [0..1] to I_SupDmndAllDocSupSourceT  as _SupSrceText            on  $projection.SupAssgmtSource = _SupSrceText.SupAssgmtSource
                                                                              and _SupSrceText.Language       = $session.system_language
{
       @ObjectModel.text.association: '_ProductText'
  key  Supply.Material,
       @ObjectModel.text.association: '_Plant'
  key  Supply.Plant,
  key  Supply.Batch,
  key  Supply.StorageLocation,
       @EndUserText.label: 'Supply Document No.'
  key  Supply.SupplyNumber,
       @EndUserText.label: 'Supply Document Item'
  key  Supply.SupplyItem,
       @EndUserText.label: 'Supply Schedule Line'
  key  Supply.SupplyScheduleLine,
       @EndUserText.label: 'Supply Delivery Date'
  key  Supply.ProductAvailabilityDate,
       @ObjectModel.text.association: '_SupText'
       @EndUserText.label: 'Supply Type'
  key  Supply.AssignedSupplyType,
       @ObjectModel.text.association: '_CatText'
       @EndUserText.label: 'Reference Type'
  key  Rel.PurchasingDocumentCategory,
       @EndUserText.label: 'Requested Delivery Date'
       Supply.RequestedDeliveryDate,
       @EndUserText.label: 'Referenced Quantity'
       @DefaultAggregation: #SUM
       @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
       Rel.ReleasedQuantity,
       @ObjectModel.foreignKey.association: '_BaseUnit'
       Supply.BaseUnit,
       @EndUserText.label: 'Year'
       @Semantics.calendar.year: true
       CalDate.CalendarYear,
       @EndUserText.label: 'Month'
       @Semantics.calendar.month: true
       @ObjectModel.text.element: 'CalendarMonthName'
       CalDate.CalendarMonth,
       @Semantics.text: true
       @EndUserText.label: 'Month'
       CalMonth.CalendarMonthName,
       @EndUserText.label: 'Week'
       @Semantics.calendar.week: true
       concat_with_space( ARunDisplayTimeUnitText, CalDate.CalendarWeek, 1)                    as CalendarWeek,
       @EndUserText.label: 'Day'
       @Semantics.calendar.dayOfMonth: true
       CalDate.CalendarDay,
       @ObjectModel.text.association: '_ProductGroupText'
       Supply.MaterialGroup,
       @ObjectModel.text.association: '_ProductTypeText'
       @EndUserText.label: 'Product Type'
       MaterialType,
       @EndUserText.label: 'Supply Source'
       @ObjectModel.text.association: '_SupSrceText'
       Supply.SupAssgmtSource,
       @EndUserText.label: 'Generic Article'
       Supply.CrossPlantConfigurableProduct,
       @ObjectModel.text.association: '_SalesOrgText'
       Plant.SalesOrganization,
       @ObjectModel.text.association: '_DistrChnl'
       Plant.DistributionChannel,
       @ObjectModel.text.association: '_Divn'
       Plant.Division,
       @ObjectModel.text.association: '_SalesDist'
       Plant.SalesDistrict,
       @ObjectModel.text.association: '_Customer'
       coalesce( Supply.Customer, coalesce( Plant.PlantCustomer, '') )                         as Customer,
       @ObjectModel.text.association: '_CompanyCode'
       coalesce( Supply.CompanyCode, coalesce( Plant.CompanyCode, '') )                        as CompanyCode,
       @ObjectModel.text.association: '_PurchasingOrganization'
       coalesce( Supply.PurchasingOrganization, coalesce( Plant.PurchasingOrganization, '' ) ) as PurchasingOrganization,
       @ObjectModel.text.association: '_PurchasingGroup'
       Supply.PurchasingGroup,
       @Semantics.unitOfMeasure: true
       cast( ' ' as meins ) as SupAssgmtAggrgQtyUnit,
       @Semantics.amount.currencyCode: 'DocumentCurrency'
       Supply.NetPriceAmount,
       @Semantics.currencyCode: true
       Supply.DocumentCurrency,
       //Associations

       _ProductText,
       _ProductGroupText,
       _ProductTypeText,
       @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
       _SupSrceText,
       _SalesOrgText,
       _DistrChnl,
       _Divn,
       _SalesDist,
       _Plant,
       _CompanyCode,
       _Customer,
       _BaseUnit,
       _PurchasingOrganization,
       _PurchasingGroup,
       _CatText,
       @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
       _SupText
}
where
  Rel.ReleasedQuantity > 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARUNCALENDARDATE",
"I_ARUNTIMEUNITTEXT",
"I_CALENDARMONTHNAME",
"I_SUPDMNDALLDOCPURGCONTR",
"I_SUPDMNDOVWPLANT",
"P_SUPDMNDALLDOCPURGCONTRREL"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_PLANT",
"I_PRODUCTGROUPTEXT",
"I_PRODUCTTEXT",
"I_PRODUCTTYPETEXT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURGDOCUMENTCATEGORYTEXT",
"I_SALESDISTRICTTEXT",
"I_SALESORGANIZATIONTEXT",
"I_SUPDMNDALLDOCSUPSOURCET",
"I_SUPDMNDALLDOCSUPTYPET",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/