I_SupDmndAllDocPurToOrdAssgC

@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics: {
  dataCategory: #CUBE,
  internalName:#LOCAL
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADPTOAC',
  compiler.compareFilter: true,
  preserveKey:true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XXL
   }
}
@Metadata:{
  allowExtensions:              true,
  ignorePropagatedAnnotations:  true
}
@EndUserText.label: 'Cube View for Purchase To Order Assignment Details'
define view I_SupDmndAllDocPurToOrdAssgC
  as select from    P_ARunAssgmtSupType  as Assgmt
    inner join      I_SupDmndOvwPlant    as Plant            on Assgmt.Plant = Plant.Plant
    left outer join I_SupDmndAllDocSDItm as Demand           on  Assgmt.RequirementDocumentNumber = Demand.RequirementDocumentNumber
                                                             and Assgmt.RequirementDocumentItem   = Demand.RequirementDocumentItem
                                                             and Assgmt.RequestedDate             = Demand.RequestedDate
                                                             and Assgmt.ProductAvailabilityDate   = Demand.ProductAvailabilityDate
                                                             and Assgmt.RequirementType           = Demand.RequirementType
    left outer join I_ARunCalendarDate   as CalDate          on Assgmt.ProductAvailabilityDate = CalDate.CalendarDate
    left outer join I_CalendarMonthName  as CalMonth         on CalDate.CalendarMonth = CalMonth.CalendarMonth
    left outer join I_ARunTimeUnitText   as ARunTimeUnitText on  ARunTimeUnitText.ARunDisplayTimeUnit = '02'
                                                             and ARunTimeUnitText.Language            = $session.system_language
  association [0..1] to I_ProductText             as _ProductText      on  $projection.Material  = _ProductText.Product
                                                                       and _ProductText.Language = $session.system_language
  association [0..1] to I_ProductGroupText        as _ProductGroupText on  $projection.MaterialGroup  = _ProductGroupText.MaterialGroup
                                                                       and _ProductGroupText.Language = $session.system_language
  //Should it be replaced with I_MaterialGroupText as ProductGroup has status Deprecated?

  association [0..1] to I_ProductTypeText         as _ProductTypeText  on  $projection.MaterialType  = _ProductTypeText.ProductType
                                                                       and _ProductTypeText.Language = $session.system_language
  association [0..1] to I_SalesOrganizationText   as _SalesOrgText     on  $projection.SalesOrganization = _SalesOrgText.SalesOrganization
                                                                       and _SalesOrgText.Language        = $session.system_language
  association [0..1] to I_DistributionChannelText as _DistrChnl        on  $projection.DistributionChannel = _DistrChnl.DistributionChannel
                                                                       and _DistrChnl.Language             = $session.system_language
  association [0..1] to I_DivisionText            as _Divn             on  $projection.Division = _Divn.Division
                                                                       and _Divn.Language       = $session.system_language
  association [0..1] to I_SalesDistrictText       as _SalesDist        on  $projection.SalesDistrict = _SalesDist.SalesDistrict
                                                                       and _SalesDist.Language       = $session.system_language
  association [0..1] to I_Plant                   as _Plant            on  $projection.Plant = _Plant.Plant
  association [0..1] to I_CompanyCode             as _CompanyCode      on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Customer                as _Customer         on  $projection.Customer = _Customer.Customer
  association [0..1] to I_UnitOfMeasure           as _BaseUnit         on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_SupDmndAllDocRqmtTypeT  as _RqmtText         on  $projection.RequirementType = _RqmtText.RequirementType
                                                                       and _RqmtText.Language          = $session.system_language
  association [0..1] to I_SupDmndAllDocSupTypeT   as _SupText          on  $projection.AssignedSupplyType = _SupText.AssignedSupplyType
                                                                       and _SupText.Language              = $session.system_language
  association [0..1] to I_SupDmndAllDocSupSourceT as _SupSrceText      on  $projection.SupAssgmtSource = _SupSrceText.SupAssgmtSource
                                                                       and _SupSrceText.Language       = $session.system_language
{
      @EndUserText.label: 'Requirement Document Number'
  key Demand.RequirementDocumentNumber,
      @EndUserText.label: 'Requirement Document Item'
  key Demand.RequirementDocumentItem,
      @EndUserText.label: 'Requested Date'
  key Demand.RequestedDate,
      @EndUserText.label: 'Delivery Date'
  key Demand.ProductAvailabilityDate,
      @ObjectModel.text.association: '_RqmtText'
      @EndUserText.label: 'Requirement Type'
  key Demand.RequirementType,
      @ObjectModel.text.association: '_SupText'
      @EndUserText.label: 'Supply Type'
  key Assgmt.AssignedSupplyType,
      @ObjectModel.text.association: '_SupSrceText'
      @EndUserText.label: 'Supply Source'
  key Assgmt.SupAssgmtSource,
      @EndUserText.label: 'Requested Delivery Date'
      Demand.RequestedDeliveryDate,
      @EndUserText.label: 'Total Assigned Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      Assgmt.AssignedQuantityInBaseUnit,
      @EndUserText.label: 'Normal Assigned Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      Assgmt.NormalAssignedQuantityInBsUnt,
      @EndUserText.label: 'Preview Assigned Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      Assgmt.PreviewAssignedQuantityInBsUnt,
      @EndUserText.label: 'Temporary Assigned Quantity'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      Assgmt.ARunTmpAssignedQuantityInBsUnt,
      @ObjectModel.foreignKey.association: '_BaseUnit'
      Demand.BaseUnit,
      @Semantics.calendar.year: true
      @EndUserText.label: 'Year'
      CalDate.CalendarYear,
      @EndUserText.label: 'Month'
      @Semantics.calendar.month: true
      @ObjectModel.text.element: 'CalendarMonthName'
      CalDate.CalendarMonth,
      @Semantics.text: true
      @EndUserText.label: 'Month'
      CalMonth.CalendarMonthName,
      @EndUserText.label: 'Week'
      @Semantics.calendar.week: true
      concat_with_space( ARunDisplayTimeUnitText, CalDate.CalendarWeek, 1)             as CalendarWeek,
      @EndUserText.label: 'Day'
      @Semantics.calendar.dayOfMonth: true
      CalDate.CalendarDay,
      @ObjectModel.text.association: '_ProductText'
      @EndUserText.label: 'Product'
      Demand.Material,
      @ObjectModel.text.association: '_ProductGroupText'
      @EndUserText.label: 'Product Group'
      Demand.MaterialGroup,
      @ObjectModel.text.association: '_ProductTypeText'
      @EndUserText.label: 'Product Type'
      MaterialType,
      @EndUserText.label: 'Generic Article'
      Demand.CrossPlantConfigurableProduct,
      @ObjectModel.text.association: '_Plant'
      Demand.Plant,
      @ObjectModel.text.association: '_SalesOrgText'
      coalesce( Demand.SalesOrganization, coalesce( Plant.SalesOrganization, '' ) )    as SalesOrganization,
      @ObjectModel.text.association: '_DistrChnl'
      coalesce( Demand.DistributionChannel, coalesce( Plant.DistributionChannel, '') ) as DistributionChannel,
      @ObjectModel.text.association: '_Divn'
      coalesce( Demand.Division, coalesce( Plant.Division, '') )                       as Division,
      @ObjectModel.text.association: '_SalesDist'
      coalesce( Demand.SalesDistrict, coalesce( Plant.SalesDistrict, '') )             as SalesDistrict,
      @ObjectModel.text.association: '_Customer'
      coalesce( Demand.SoldToParty, coalesce( Plant.PlantCustomer, '') )               as Customer,
      @ObjectModel.text.association: '_CompanyCode'
      coalesce( Demand.CompanyCode, coalesce( Plant.CompanyCode, '') )                 as CompanyCode,
      Demand.StorageLocation,
      @Semantics.unitOfMeasure: true
      cast( ' ' as meins ) as SupAssgmtAggrgQtyUnit,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      Demand.NetPriceAmount,
      @Semantics.currencyCode: true
      Demand.DocumentCurrency,
      //Associations

      _ProductText,
      _ProductGroupText,
      _ProductTypeText,
      _SalesOrgText,
      _DistrChnl,
      _Divn,
      _SalesDist,
      _Plant,
      _CompanyCode,
      _Customer,
      _BaseUnit,
      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
      _SupText,
      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
      _SupSrceText,
      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
      _RqmtText
}
where
      Assgmt.RequirementType            = 'VE' -- Purchase To Order
  and Demand.RequestedRqmtQtyInBaseUnit > 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARUNCALENDARDATE",
"I_ARUNTIMEUNITTEXT",
"I_CALENDARMONTHNAME",
"I_SUPDMNDALLDOCSDITM",
"I_SUPDMNDOVWPLANT",
"P_ARUNASSGMTSUPTYPE"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_PLANT",
"I_PRODUCTGROUPTEXT",
"I_PRODUCTTEXT",
"I_PRODUCTTYPETEXT",
"I_SALESDISTRICTTEXT",
"I_SALESORGANIZATIONTEXT",
"I_SUPDMNDALLDOCRQMTTYPET",
"I_SUPDMNDALLDOCSUPSOURCET",
"I_SUPDMNDALLDOCSUPTYPET",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/