I_SupDmndAllDocGdsIssdDeliv

DDL: I_SUPDMNDALLDOCGDSISSDDELIV Type: view BASIC

View for Goods Issued Deliveries

I_SupDmndAllDocGdsIssdDeliv is a Basic CDS View that provides data about "View for Goods Issued Deliveries" in SAP S/4HANA. It reads from 4 data sources (kna1, likp, lips, I_SupDmndMaterialPlant) and exposes 30 fields.

4 data source(s) 30 fields

Data Sources (4)

SourceAliasJoin Type
kna1 kna1 inner
likp likp inner
lips lips from
I_SupDmndMaterialPlant marc inner

Annotations (10)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #NOT_REQUIRED view
AbapCatalog.sqlViewName ISUPDMNDADGIDLV view
AbapCatalog.compiler.compareFilter true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #XXL view
EndUserText.label View for Goods Issued Deliveries view

Fields (30)

KeyFieldSource TableSource FieldDescription
RequirementDocumentNumber lips vbeln
RequirementDocumentItem lips posnr
HigherLvlItmOfBatSpltItm lips uecha
RequirementType
RequestedDate lips mbdat
ProductAvailabilityDate lips mbdat
RequestedDeliveryDate lips mbdat
DeliveredQuantity lips ormng
BaseUnit lips meins
PlannedGoodsIssueDate likp wadat
ActualGoodsMovementDate likp wadat_ist
GIToPlndGIDelayInDays
ShippingType likp vsart
Material lips matnr
Plant lips werks
MaterialGroup lips matkl
MaterialType I_SupDmndMaterialPlant MaterialType
CrossPlantConfigurableProduct I_SupDmndMaterialPlant CrossPlantConfigurableProduct
RequirementSegment lips sgt_rcat
SDDocumentCategory likp vbtyp
DeliveryDocumentType likp lfart
SalesOrganization likp vkorg
DistributionChannel lips vtweg
Division lips spart
SalesDistrict likp bzirk
SoldToParty likp kunag
StorageLocation lips lgort
IsBusinessPurposeCompleted kna1 cvp_xblck
NetPriceAmount lips netpr
DocumentCurrency likp waerk 
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADGIDLV',
  compiler.compareFilter: true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #X,
     sizeCategory:   #XXL
   }
}
@EndUserText.label: 'View for Goods Issued Deliveries'
define view I_SupDmndAllDocGdsIssdDeliv
  as select from lips                   as lips
    inner join   likp                   as likp on lips.vbeln = likp.vbeln
    inner join   kna1                   as kna1 on likp.kunnr = kna1.kunnr
    inner join   I_SupDmndMaterialPlant as marc on  lips.matnr = marc.Material
                                                and lips.werks = marc.Plant
{
  lips.vbeln                                      as RequirementDocumentNumber,
  lips.posnr                                      as RequirementDocumentItem,
  lips.uecha                                      as HigherLvlItmOfBatSpltItm,
  'VJ'                                            as RequirementType,
  lips.mbdat                                      as RequestedDate,
  lips.mbdat                                      as ProductAvailabilityDate,
  lips.mbdat                                      as RequestedDeliveryDate,
  lips.ormng                                      as DeliveredQuantity,
  lips.meins                                      as BaseUnit,
  likp.wadat                                      as PlannedGoodsIssueDate,
  likp.wadat_ist                                  as ActualGoodsMovementDate,
  // Planned GI Date - Actual GI Date

  dats_days_between( likp.wadat, likp.wadat_ist ) as GIToPlndGIDelayInDays,
  likp.vsart                                      as ShippingType,
  lips.matnr                                      as Material,
  lips.werks                                      as Plant,
  lips.matkl                                      as MaterialGroup,
  marc.MaterialType,
  marc.CrossPlantConfigurableProduct,
  lips.sgt_rcat                                   as RequirementSegment,
  likp.vbtyp                                      as SDDocumentCategory,
  likp.lfart                                      as DeliveryDocumentType,
  likp.vkorg                                      as SalesOrganization,
  lips.vtweg                                      as DistributionChannel,
  lips.spart                                      as Division,
  likp.bzirk                                      as SalesDistrict,
  likp.kunag                                      as SoldToParty,
  lips.lgort                                      as StorageLocation,
  kna1.cvp_xblck                                  as IsBusinessPurposeCompleted,
  lips.netpr                                      as NetPriceAmount,
  likp.waerk                                      as DocumentCurrency
}
where
      lips.wbsta = 'C' --> Good Movement completed ( PGI Done )
  and lips.lfimg > 0
  and likp.vbtyp = 'J'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPDMNDMATERIALPLANT",
"KNA1",
"LIKP",
"LIPS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More