I_SubscrpnProdSpec

@AbapCatalog.sqlViewName: 'ISPRODSPEC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Subscription Product Specification'

@VDM.viewType: #BASIC

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory : #M
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE


define view I_SubscrpnProdSpec
  as select from P_SubscrpnProdSpec as SubscrpnProdSpec

  association [0..1] to I_Product         as _Product                      on _Product.Product = $projection.Product
  association [1..1] to I_Producttype     as _ProductType                  on _ProductType.ProductType = $projection.ProductType
  association [0..*] to I_ProductText     as _ProductText                  on _ProductText.Product = $projection.Product
  association [0..1] to I_ProductGroup    as _ProductGroup                 on _ProductGroup.MaterialGroup = $projection.ProductGroup
  association [1..1] to I_User            as _CreatedByUser                on _CreatedByUser.UserID = $projection.CreatedByUser
  association [0..1] to I_User            as _LastChangedByUser            on _LastChangedByUser.UserID = $projection.LastChangedByUser
  association [1..1] to I_UserContactCard as _CreatedByUserContactCard     on $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard as _LastChangedByUserContactCard on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID



{
      @ObjectModel.readOnly: true
  key SubscrpnProdSpec.SubscrpnProdSpecUUID         as SubscrpnProdSpecUUID,
      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      @Semantics.user.createdBy: true
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.CreatedByUser                as CreatedByUser,
      _CreatedByUser,
      _CreatedByUserContactCard,
      @Semantics.systemDateTime.createdAt: true
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.CreationDateTime             as CreationDateTime,
      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      @Semantics.user.lastChangedBy: true
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.LastChangedByUser            as LastChangedByUser,
      _LastChangedByUser,
      _LastChangedByUserContactCard,
      @Semantics.systemDateTime.lastChangedAt: true
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.LastChangeDateTime           as LastChangeDateTime,
      @EndUserText.label: 'Product'
      @ObjectModel.text.association: '_ProductText'
      SubscrpnProdSpec.Product                      as Product,
      _ProductText,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.ProductUUID                  as ProductUUID,
      @EndUserText.label: 'Product Type'
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.ProductType                  as ProductType,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.ProductGroup                 as ProductGroup,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.AuthorizationGroup           as AuthorizationGroup,
      SubscrpnProdSpec.SubscrpnProdTechRsceSchema   as SubscrpnProdTechRsceSchema,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.ProductIsConfigurable        as ProductIsConfigurable,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.BaseUnit                     as BaseUnit,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.CABillgCycle                 as CABillgCycle,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.SubscrpnProdBillgCycDetn     as SubscrpnProdBillgCycDetn,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.SubscriptionProductPurpose   as SubscriptionProductPurpose,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.ContractAutoRenewalType      as ContractAutoRenewalType,
      @ObjectModel.readOnly: true
      SubscrpnProdSpec.SubscrpnProdTechRsceIsActive as SubscrpnProdTechRsceIsActive,

      _Product,
      _ProductGroup,
      _ProductType




}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_SUBSCRPNPRODSPEC"
],
"ASSOCIATED":
[
"I_PRODUCT",
"I_PRODUCTGROUP",
"I_PRODUCTTEXT",
"I_PRODUCTTYPE",
"I_USER",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/