I_SubscriptionOrder

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Subscription Order'
@ObjectModel: {
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}

define view entity I_SubscriptionOrder
  as select from I_ServiceDocumentEnhcd
  association [0..1] to I_StatusObjectUUIDStatus       as _SrvcOrdStatus               on  $projection.SubscriptionOrderUUID = _SrvcOrdStatus.StatusObjectUUID
                                                                                       and (
                                                                                          _SrvcOrdStatus.StatusCode          = 'I1002'
                                                                                          or _SrvcOrdStatus.StatusCode       = 'I1003'
                                                                                          or _SrvcOrdStatus.StatusCode       = 'I1004'
                                                                                          or _SrvcOrdStatus.StatusCode       = 'I1005'
                                                                                        )
                                                                                       and _SrvcOrdStatus.StatusIsActive     = 'X'

  association [0..*] to I_SubscriptionOrderItem        as _SubscriptionOrderItem       on  $projection.SubscriptionOrder = _SubscriptionOrderItem.SubscriptionOrder
  association [0..*] to I_SubscriptionOrderPartner     as _SubscriptionOrderPartner    on  $projection.SubscriptionOrder = _SubscriptionOrderPartner.SubscriptionOrder
  association [0..*] to I_SubscriptionOrderUserStatus  as _SubscriptionOrderUserStatus on  $projection.SubscriptionOrder = _SubscriptionOrderUserStatus.SubscriptionOrder
  association [0..1] to I_SubscrpnOrdExternalReference as _ExternalReference         on  $projection.SubscriptionOrder = _ExternalReference.SubscriptionOrder
  association [0..*] to I_SubscrpnOrdFUPSubscrpnContr  as _FollowUpContract            on  $projection.SubscriptionOrder = _FollowUpContract.SubscriptionOrder
  association [0..*] to I_SubscrpnOrdFUPSalesOrder     as _FollowUpSalesOrder          on  $projection.SubscriptionOrder = _FollowUpSalesOrder.SubscriptionOrder
  association [0..*] to I_ChgOrdPrdcssrBusSolnQtan     as _PredecessorQuotation        on  $projection.SubscriptionOrder = _PredecessorQuotation.SubscriptionOrder
  association [0..*] to I_ChgOrdPrdcssrSubscrpnContr   as _PredecessorContract         on  $projection.SubscriptionOrder = _PredecessorContract.SubscriptionOrder
  association [0..*] to I_WBSElementBasicData          as _WBSElement                  on  $projection.WBSElementExternalID = _WBSElement.WBSElementExternalID
{
  key ServiceDocument                               as SubscriptionOrder,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType,
      ServiceDocumentUUID                           as SubscriptionOrderUUID,
      ServiceDocumentDescription                    as SubscriptionOrderDescription,
      ServiceDocCreationDateTime                    as CreationDateTime,
      ServiceDocChangedDateTime                     as LastChangeDateTime,
      ServiceDocumentCreatedByUser                  as CreatedByUser,
      ServiceDocumentChangedByUser                  as LastChangedByUser,
      // Sales Set

      PurchaseOrderByCustomer,


      // Status

      cast( case _SrvcOrdStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end       as   xfeld preserving type     )    as SubscrpnOrderIsNew,
      cast( case _SrvcOrdStatus.StatusCode
      when 'I1003' then 'X'
      else ' '
      end      as   xfeld preserving type     )     as SubscrpnOrdIsInProcess,
      cast( case _SrvcOrdStatus.StatusCode
      when 'I1004' then 'X'
      else ' '
      end      as   xfeld preserving type     )     as SubscrpnOrdIsReleased,
      cast( case _SrvcOrdStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end     as   xfeld preserving type     )      as SubscrpnOrdIsCompleted,
      @Semantics.booleanIndicator
      ServiceDocumentIsOpen                         as SubscrpnOrdIsOpen,
      @Semantics.booleanIndicator
      ServiceDocumentHasError                       as SubscrpnOrdHasError,
      SrvcDocRejectionStatus,


      // Partners

      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      cast( ContactPerson as abap.numc( 10 ))       as ContactPerson,
      cast( ResponsibleEmployee as abap.char( 12 )) as PersonResponsible,


      // Organizational Data

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,

      //CRM Org units

      //these feilds are only ON PREMISE

      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceOrganization,

      // Pricing Parameter Set

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      
      // WBS element  

      case SrvcDocAcctAssgmtObjectType
      when '03' then cast(SrvcDocAcctAssgmtObject as ps_posid_edit)
      else ' '
      end  as WBSElementExternalID,
      
      // All Associations Below

      _SubscriptionOrderItem,
      _SubscriptionOrderPartner,
      _SubscriptionOrderUserStatus,
      _ExternalReference,
      _FollowUpContract,
      _FollowUpSalesOrder,
      _PredecessorQuotation,
      _PredecessorContract,

      //Org Units

      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesOffice,
      _SalesGroup,

      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _ServiceOrganizationOrgUnit_2,

      // Pricing Parameter Set

      _TransactionCurrency,
      _PaymentTerms,

      _ServiceObjType,
      _ServiceDocumentType,
      _WBSElement
}
where
  ServiceObjectType = 'BUS2000265' // Subscription  Order

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_STATUSOBJECTUUIDSTATUS"
],
"ASSOCIATED":
[
"I_CHGORDPRDCSSRBUSSOLNQTAN",
"I_CHGORDPRDCSSRSUBSCRPNCONTR",
"I_CURRENCY",
"I_CUSTMGMTBUSOBJTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_PAYMENTTERMS",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCMGMTORGANIZATIONUNIT",
"I_SUBSCRIPTIONORDERITEM",
"I_SUBSCRIPTIONORDERPARTNER",
"I_SUBSCRIPTIONORDERUSERSTATUS",
"I_SUBSCRPNORDEXTERNALREFERENCE",
"I_SUBSCRPNORDFUPSALESORDER",
"I_SUBSCRPNORDFUPSUBSCRPNCONTR",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/