I_StorageLocationStdVH

DDL: I_STORAGELOCATIONSTDVH Type: view BASIC

Storage Location

I_StorageLocationStdVH is a Basic CDS View that provides data about "Storage Location" in SAP S/4HANA. It reads from 1 data source (I_StorageLocation) and exposes 8 fields with key fields Plant, StorageLocation. It has 1 association to related views.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
I_StorageLocation I_StorageLocation from

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_ConfignDeprecationCode _ConfigDeprecationCode $projection.ConfigDeprecationCode = _ConfigDeprecationCode.ConfigurationDeprecationCode and _ConfigDeprecationCode.ConfigurationDeprecationCode <> 'E'

Annotations (20)

NameValueLevelField
AbapCatalog.sqlViewName ISTORAGELOCSTDVH view
AbapCatalog.preserveKey true view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.dataMaintenance #RESTRICTED view
EndUserText.label Storage Location view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
ObjectModel.representativeKey StorageLocation view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Search.searchable true view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #NOT_REQUIRED view
AccessControl.personalData.blocking #NOT_REQUIRED view
Consumption.ranked true view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY Plant Plant
KEY StorageLocation StorageLocation
StorageLocationName StorageLocationName
ConfigDeprecationCode ConfigDeprecationCode
ConfignDeprecationCodeName
PlantName _Plant PlantName
_Plant _Plant
_ConfigDeprecationCode _ConfigDeprecationCode 
@AbapCatalog: {
                sqlViewName: 'ISTORAGELOCSTDVH',
                preserveKey: true,
                compiler.compareFilter: true,
                dataMaintenance: #RESTRICTED
              }
@EndUserText.label: 'Storage Location'
@ObjectModel: {
                usageType:{
                            sizeCategory: #S,
                            serviceQuality: #B,
                            dataClass: #CUSTOMIZING
                          },
                dataCategory: #VALUE_HELP,
                modelingPattern: #ANALYTICAL_DIMENSION,
                representativeKey: 'StorageLocation',
                supportedCapabilities: [#VALUE_HELP_PROVIDER,#ANALYTICAL_DIMENSION] //PAT2

              }
@VDM: {
        viewType: #BASIC,
        lifecycle.contract.type: #PUBLIC_LOCAL_API
      }
@Search.searchable: true
@Metadata: {
             allowExtensions: true,
             ignorePropagatedAnnotations: true
           }
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl: {
                  authorizationCheck: #NOT_REQUIRED,
                  personalData.blocking: #NOT_REQUIRED
                }
@Consumption.ranked: true

define view I_StorageLocationStdVH
  as select from I_StorageLocation
  association [1..1] to I_ConfignDeprecationCode as _ConfigDeprecationCode on  $projection.ConfigDeprecationCode                   =  _ConfigDeprecationCode.ConfigurationDeprecationCode
                                                                           and _ConfigDeprecationCode.ConfigurationDeprecationCode <> 'E'
{
      @ObjectModel.text.element: ['PlantName']
      @ObjectModel.foreignKey.association: '_Plant'
      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Consumption.valueHelpDefinition: [
        {
          entity:
            { name: 'I_PlantStdVH',
              element: 'Plant'
            }
        }
        ]
      @UI.lineItem:[{position:30}]
      @Consumption.valueHelpDefault.binding.usage: #FILTER_AND_RESULT
  key Plant,

      @ObjectModel.text.element: ['StorageLocationName']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @UI.lineItem:[{position:10}]
      @Consumption.valueHelpDefault.binding.usage: #FILTER_AND_RESULT
  key StorageLocation,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @UI.lineItem:[{position:20}]
      StorageLocationName,

      @Consumption.valueHelpDefinition: [
        {
          entity:
            { name: 'I_ConfignDeprecationCode',
              element: 'ConfigurationDeprecationCode'                 // old GFN

            }
        }
        ]
      @ObjectModel.text.element: [ 'ConfignDeprecationCodeName' ]
      ConfigDeprecationCode,
      _ConfigDeprecationCode._Text[1:Language=$session.system_language].ConfignDeprecationCodeName,
      _Plant.PlantName,
      
      /* Associations */
      @Consumption.hidden: true
      _Plant,
      _ConfigDeprecationCode
}
where
  ConfigDeprecationCode <> 'E'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CONFIGNDEPRECATIONCODE",
"I_CONFIGNDEPRECATIONCODETEXT",
"I_PLANT",
"I_STORAGELOCATION"
],
"ASSOCIATED":
[
"I_CONFIGNDEPRECATIONCODE",
"I_PLANT"
],
"BASE":
[
"I_STORAGELOCATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More