I_StockDeterminationGroupText

@AbapCatalog: {
                sqlViewName: 'ISTCKKDTRGRPTXT',
                compiler.compareFilter: true,
                preserveKey: true
              }
@ObjectModel: {
                dataCategory: #TEXT,
                representativeKey: 'StockDeterminationGroup',
                usageType: {
                             serviceQuality: #A,
                             sizeCategory: #S,
                             dataClass: #CUSTOMIZING
                           },
                 modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
                 supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
              }
@VDM: {
         lifecycle.contract.type: #PUBLIC_LOCAL_API,
         viewType: #BASIC
       }
@EndUserText.label: 'Determination Group for Stock - Text'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@Search.searchable: true
@AbapCatalog.buffering : { status : #ACTIVE, type: #FULL }
define view I_StockDeterminationGroupText
  as select from t434h
  association [0..1] to I_Language                as _Language                on  $projection.Language = _Language.Language
  association [1..1] to I_Plant                   as _Plant                   on  $projection.Plant = _Plant.Plant
  association [1..1] to I_StockDeterminationGroup as _StockDeterminationGroup on  $projection.Plant                   = _StockDeterminationGroup.Plant
                                                                              and $projection.StockDeterminationGroup = _StockDeterminationGroup.StockDeterminationGroup
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key spras as Language,
      @ObjectModel.foreignKey.association: '_Plant'
  key werks as Plant,
      @ObjectModel.foreignKey.association: '_StockDeterminationGroup'
      @ObjectModel.text.element: ['StockDeterminationGroupText']
  key eprio as StockDeterminationGroup,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      bezei as StockDeterminationGroupText,
      _Language,
      _Plant,
      _StockDeterminationGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T434H"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PLANT",
"I_STOCKDETERMINATIONGROUP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/